InputBox - Pressing Cancel doesn't exit sub

[katekoz]

I may be naive, but I expected that the default setting for pressing "Cancel" on a message box would be to exit sub. That's not the case! ? Nothing happens and it just continues on. Is there some code I need to add to get the program to end sub when "Cancel" is pressed?

Here's one of the little pieces of code with an inputbox. I have many of them throughout a few different macros.

UserID = InputBox("Enter the username you'd like to add training status for.", vbOKCancel)
DateID = InputBox("Enter the first day of the month you'd like to add training for.", vbOKCancel)

ThisWorkbook.Sheets("Training").Range("I2").Value = UserID
ThisWorkbook.Sheets("Training").Range("J2").Value = DateID

 

[MARK858]

Maybe the Syntax below?

Dim UserID as String
UserID = InputBox("Enter the username you'd like to add training status for.", vbOKCancel)
If UserID = vbNullString Then Exit Sub

 

[katekoz]

That worked! Simple, thanks! I'll add it throughout the set of macros I'm working on. Have a great day!

 

[MARK858]

You're welcome

 

[DanteAmor]

Try this

Sub test()
  Dim UserId, DateID
  UserId = InputBox("Enter the username you'd like to add training status for.", vbOKCancel)
  If StrPtr(UserId) = 0 Then
    MsgBox "The user clicked Cancel, so we will exit the subroutine now."
    Exit Sub
  ElseIf Len(UserId) = 0 Then
    MsgBox "The user clicked OK without entering anything in the InputBox!"
    Exit Sub
  Else
    MsgBox "The user entered the following..." & vbLf & vbLf & UserId
    'continue
  End If


  DateID = InputBox("Enter the first day of the month you'd like to add training for.", vbOKCancel)
  If StrPtr(DateID) = 0 Then
    MsgBox "The user clicked Cancel, so we will exit the subroutine now."
    Exit Sub
  ElseIf Len(DateID) = 0 Then
    MsgBox "The user clicked OK without entering anything in the InputBox!"
    Exit Sub
  Else
    MsgBox "The user entered the following..." & vbLf & vbLf & DateID
    'continue
  End If
  
  ThisWorkbook.Sheets("Training").Range("I2").Value = UserId
  ThisWorkbook.Sheets("Training").Range("J2").Value = DateID
End Sub