Inputbox (Dim as string, can be blank) on Cancel

[melodramatic]

I've tried looking this up, but can't find a comparable problem with cancelling at an inputbox.

I've got an inputbox that is looking for a text entry, but the odd one out here is that it can left blank at the entry point (if they don't want to filter a list). My problem is trying to get the macro to cancel out if they hit Cancel at this point. I haven't been able to figure out how to make it work.

Here's what I've got (just giving the portion of the macro with the error). Right now, you'll see that I've got the lines commented out, as without them in there, the macro works fine...

'TextFilter for Client Name
    Dim ClientFilter As String
    ClientFilter = InputBox("Type in text you want to use to filter Client/Contract search:", "Client Name Text Filter")
    'If ClientFilter = vbCancel Then
    '    MsgBox "Macro is cancelled.  The current Client Contract selection remains as is."
    '    Exit Sub
    'End If

I know that it's probably and easy solution, but my brain just won't wrap around that.

Thanks in advance for your help!

 

[Peter_SSs]

Use Application.InputBox instead. Like this

Dim ClientFilter As Variant
ClientFilter = Application.InputBox("Type in text you want to use to filter Client/Contract search:", "Client Name Text Filter")
If ClientFilter = False Then
  MsgBox "Cancelled"
Else
  'Your other code goes here
End If

 

[VBasic2008]

Your setup is not quite clear, but the following might help.

Option Explicit

Sub test()
    
    Dim ClientFilter As String
    ClientFilter = "Peter"
    Dim testClientFilter As String
    On Error Resume Next
    testClientFilter = InputBox("Type in text you want to use to filter Client/Contract search:", "Client Name Text Filter")
    On Error GoTo 0
    If testClientFilter = "" Then
        MsgBox "Macro is cancelled.  The current Client Contract selection remains as is."
    Else
        ClientFilter = testClientFilter
    End If
    Debug.Print ClientFilter

End Sub

 

[melodramatic]

Peter_SSs - your correction worked perfectly, with very little change. Thank you!

VBasic2008 - since I already tried Peter's and it worked, I'm not going to use yours, but I appreciate your quick assistance.

 

[VBasic2008]

When using InputBox you cannot easily (I saw a complicated solution once) find out if the user canceled or just left the box empty. The following shows how easy it is with Application.InputBox:

Sub test2()
  
    Dim ClientFilter As String
    ClientFilter = "Peter"
    Dim testClientFilter As Variant
    testClientFilter = Application.InputBox("Type in text you want to use to filter Client/Contract search:", "Client Name Text Filter")
    Select Case testClientFilter
        Case False
            MsgBox "User pressed Cancel."
        Case ""
            MsgBox "User left the box empty and pressed OK."
        Case Else
            ClientFilter = testClientFilter
    End Select
    Debug.Print ClientFilter

End Sub

 

[Peter_SSs]

Peter_SSs - your correction worked perfectly, with very little change. Thank you!

You're welcome. Thanks for the follow-up.