Infinite Loop Correction

[lazyandsenile]

Hello,
I have been trying a lot of different methods to achieve the desired result however close but no cigar.
The code below does what I need but I have an infinite loop which results in a run-time error.

Sub DeleteBlankTesting()​

' This code deletes empty rows if GRNSTATE is empty. Error to end loop​

Sheets("GREEN ATMS").Select​

Do While Not IsEmpty("GRNSTATE")​

Range("GRNSTATE").SpecialCells(xlCellTypeBlanks).Select​

ActiveCell.EntireRow.Delete​

Loop​

End Sub​

The end goal in to find all the blank cells in table range "GRNSTATE" and then delete the entire row.

Any help on this would be legendary. This is the last piece to complete my spreadsheet.

Thank you in advance.

 

[TryingToLearn]

Not sure if your named range is multiple columns but if not, try this:

Sub DeleteBlankTesting()
' This code deletes empty rows if GRNSTATE is empty. Error to end loop
Sheets("GREEN ATMS").Select
Dim x
Dim c As Range
For x = Right(Range("grnstate").Address, Len(Range("grnstate").Address) - (InStrRev(Range("grnstate").Address, "$"))) _
    To Range("grnstate").Row Step -1
Set c = Cells(x, Range("grnstate").Column)
Debug.Print c.Address
If c = "" Then c.EntireRow.Delete
Next x
End Sub

 

[lazyandsenile]

QUESTIONS ANSWERED.
This is bang on. Thank you so much.

Not sure if your named range is multiple columns but if not, try this:

Sub DeleteBlankTesting()
' This code deletes empty rows if GRNSTATE is empty. Error to end loop
Sheets("GREEN ATMS").Select
Dim x
Dim c As Range
For x = Right(Range("grnstate").Address, Len(Range("grnstate").Address) - (InStrRev(Range("grnstate").Address, "$"))) _
    To Range("grnstate").Row Step -1
Set c = Cells(x, Range("grnstate").Column)
Debug.Print c.Address
If c = "" Then c.EntireRow.Delete
Next x
End Sub

 

[StephenCrump]

... or, without looping:

On Error Resume Next
Range("GRNSTATE").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
On Error GoTo 0

I'm also assuming that GRNSTATE has only one column.

If it has multiple columns, presumably you'll want to be deleting rows only where all values in the row are blank (?) which would require slightly different code.

(Note that .SpecialCells(xlCellTypeBlanks) won't include cells where a formula is returning the blank).

 

[StephenCrump]

For x = Right(Range("grnstate").Address, Len(Range("grnstate").Address) - (InStrRev(Range("grnstate").Address, "$"))) _
    To Range("grnstate").Row Step -1
    Set c = Cells(x, Range("grnstate").Column)
Next x

And just by the way, you could do this more simply:

With Range("GRNSTATE")
    For x = .Rows.Count To 1 Step -1
        Set c = .Cells(x, 1)
    Next x
End With

 

[TryingToLearn]

And just by the way, you could do this more simply:

With Range("GRNSTATE")
    For x = .Rows.Count To 1 Step -1
        Set c = .Cells(x, 1)
    Next x
End With

Thank You!!!