INDEX MATCH 2 Criteria 1st Occurance

[hrayani]

Hello Friends,

I am in need of an index match formula with 2 criteria to match and return 1st Occurance than 2nd and so on

Here is a sample data with headings in Row 1
Data starting from Row 2 (Coumns A,B,C)


REF#------Name----------Size

414--------Flat Sheet-----125x200
414--------Flat Sheet-----240x200
414--------Fitted Sheet---150x210
414--------Pillow----------50x70
414--------Duvet----------125x200



Cell D1 = 414
Cell E1 = Flat Sheet
Cell F1 = Formula required to give the first occurance ( 125x200)
Cell F2 = Formula required to give the second occurance (240x200)


Any help would be appreciated.

Regards,

Humayun

 

[Fluff]

How about
=IFERROR(INDEX($C$2:$C$6,AGGREGATE(15,6,(ROW($C$2:$C$6)-ROW($C$2)+1)/(($A$2:$A$6=$D$1)*($B$2:$B$6=$E$1)),ROWS($A$1:$A1))),"")

 

[hrayani]

Hi Fluff,

Thanks for the reply.... Your formula is working perfect

I was using this formula with a single criteria

=IFERROR(INDEX($B$2:$B$6,SMALL(IF($A$2:$A$6=$D$1,ROW($A$2:$A$6)-1,""),ROW(1:1))),"")

Is it possible to add the second criteria in the above formula. Your formula is very advance i guess (working perfect though).
Finding it difficult to understand.

 

[Fluff]

How about
=IFERROR(INDEX($C$2:$C$6,SMALL(IF(($A$2:$A$6=$D$1)*($B$2:$B$6=$E$1),ROW($A$2:$A$6)-1,""),ROW(1:1))),"")

 

[hrayani]

Thanks Fluff,

Working Perfect

 

[Fluff]

You're welcome & thanks for the feedback