if username & password on userform are error then close file totally after three times

[Amer Omar]

Hi,
I search for project when username & password in TB1,TB2 are error then should close the file totally after three tries without close others files are open , I would when run the form should not show the sheets if username & password in TB1,TB2 are corrct then just show one sheet is the first contains button to show the form and hide the others .
I see some codes if username & password are error and try to open the file again then will show sheets I don't want this way .
always show the form without show contents file when try to write username & password in TB1,TB2 until will be correct the entiries .
thanks in advanced

 

[Domenic]

The following code will prompt the user to enter the username and password, and close the workbook when the user fails three times to enter the correct credentials. Note that you'll need to make the necessary changes where specified in the code, and change the name of the controls accordingly.

Control Name	Purpose
usernameTextbox	Textbox to enter the username
passwordTextbox	Textbox to enter the password
loginButton	Button to login
loginForm	Userform to login

[ThisWorkbook module]

Option Explicit

Private Sub Workbook_Open()

    If Not loginForm.isLoginSuccessful() Then
        ThisWorkbook.Saved = True
        ThisWorkbook.Close SaveChanges:=False
        Exit Sub
    End If
   
End Sub

[UserForm module]

Option Explicit

Const USERNAME As String = "Username" 'change the username as desired
Const PASSWORD As String = "Password" 'change the password as desired
Const LOGIN_ATTEMPTS_ALLOWED As Long = 3 'change as desired

Dim m_success As Boolean

Public Function isLoginSuccessful() As Boolean

    m_success = False
   
    loginForm.Show vbModal
   
    isLoginSuccessful = m_success
   
End Function

Private Sub loginButton_Click()

    Static loginAttempts As Long
   
    With Me.usernameTextbox
        If Len(.Value) = 0 Then
            .SetFocus
            MsgBox "Please enter the username", vbExclamation, "Username"
            Exit Sub
        End If
    End With
   
    With Me.passwordTextbox
        If Len(.Value) = 0 Then
            .SetFocus
            MsgBox "Please enter the password", vbExclamation, "Password"
            Exit Sub
        End If
    End With
   
    If Me.usernameTextbox.Value = USERNAME And Me.passwordTextbox.Value = PASSWORD Then
        m_success = True
        Unload Me
        Exit Sub
    End If
   
    loginAttempts = loginAttempts + 1
   
    If loginAttempts >= LOGIN_ATTEMPTS_ALLOWED Then
        MsgBox "Too many login attempts", vbCritical, "Login"
        m_success = False
        Unload Me
        Exit Sub
    End If
       
    MsgBox "Username and/or password is invalid", vbExclamation, "Invalid"
   
End Sub

Hope this helps!

 

[Amer Omar]

Hi
thanks for this project, but the question is when open file should just the form without show the file( contents sheets) .
I see the file is visible and I should enable the macro , but I see some project in the internet hide workbook when run the form if the user and password are correct then the workbook is visible otherwise just the form keep visible until the user and password are correct or close the file .
is it possible?

 

[Domenic]

In that case, try the following instead...

[ThisWorkbook module]

Option Explicit


Private Sub Workbook_Open()
    
    Dim uf As loginForm
    Set uf = New loginForm
    
    uf.Show vbModal
    
End Sub

[UserForm module]

Option Explicit

Const USERNAME As String = "Username" 'change the username as desired
Const PASSWORD As String = "Password" 'change the password as desired
Const LOGIN_ATTEMPTS_ALLOWED As Long = 3 'change as desired

Dim m_success As Boolean

Private Sub cancelButton_Click()

    m_success = False
    
    Unload Me
    
End Sub

Private Sub loginButton_Click()

    Static loginAttempts As Long
    
    With Me.usernameTextbox
        If Len(.Value) = 0 Then
            .SetFocus
            MsgBox "Please enter the username", vbExclamation, "Username"
            Exit Sub
        End If
    End With
    
    With Me.passwordTextbox
        If Len(.Value) = 0 Then
            .SetFocus
            MsgBox "Please enter the password", vbExclamation, "Password"
            Exit Sub
        End If
    End With
    
    If Me.usernameTextbox.Value = USERNAME And Me.passwordTextbox.Value = PASSWORD Then
        m_success = True
        Unload Me
        Exit Sub
    End If
    
    loginAttempts = loginAttempts + 1
    
    If loginAttempts >= LOGIN_ATTEMPTS_ALLOWED Then
        MsgBox "Too many login attempts", vbCritical, "Login"
        m_success = False
        Unload Me
        Exit Sub
    End If
        
    MsgBox "Username and/or password is invalid", vbExclamation, "Invalid"
    
End Sub

Private Sub UserForm_Initialize()
    ThisWorkbook.Windows(1).Visible = False
End Sub

Private Sub UserForm_Terminate()
    If m_success Then
        ThisWorkbook.Windows(1).Visible = True
        ThisWorkbook.Saved = True
    Else
        ThisWorkbook.Close savechanges:=False
    End If
End Sub

Hope this helps!

 

[Amer Omar]

Awesome !
many thanks,buddy.

 

[Domenic]

You're very welcome, I'm glad I could help.

Cheers!