If/Then with Multiple Ifs

[helpexcel]

Hi - I'm wondering if I can define a letter, "X", to represent multiple values in an If/Then statement. The code is not complete and just an example of what i would like to do:

x="Apples", "Oranges", "Pears", "Grapes", "Banana", "Strawberry", "Blueberry"

If Sheet1.Range("A1") = x Then

Rest of Code

End If

 

[Fluff]

You could do something like

Sub helpexcel()
   Dim St As String
   St = "Apples|Oranges|Pears|Grapes"
   If InStr(1, St, "|" & Sheet1.Range("A1") & "|", vbTextCompare) > 0 Then
     'do something
   End If
End Sub

 

[JoeMo]

Like this:

Dim x as variant, i as long
x=Array("Apples", "Oranges", "Pears", "Grapes", "Banana", "Strawberry", "Blueberry")
for i = Lbound(x) to Ubound(x)
     If Sheet1.Range("A1") = x(i) then
       'rest of code

 

[Joe4]

You could also use a Case statement. This is really helpful if you have other options that you want to handle differently.
Here is a simple example based on your description:

Sub Test()

    Select Case Sheet1.Range("A1")
        Case "Apples", "Oranges", "Pears", "Grapes", "Banana", "Strawberry", "Blueberry"
            MsgBox "Item found in list"
        Case Else
            MsgBox "Item NOT found in list"
    End Select
    
End Sub

 

[DanteAmor]

If the case sensitivity does not matter, then:

Sub test()
  Dim x As String
  x = "Apples, Oranges, Pears, Grapes, Banana, Strawberry, Blueberry[SIZE=3][COLOR=#ff0000][B],[/B][/COLOR][/SIZE]"
  If LCase(x) Like "*" & LCase(Sheet1.Range("A1")) & "[B],[/B]*" Then
    'Rest of Code
  End If
End Sub

Note: It is important to put the comma shown in red.


------------

@Fluff, Missing | at the beginning and end of the string.

St = "[B][COLOR=#ff0000]|[/COLOR][/B]Apples|Oranges|Pears|Grapes[B][COLOR=#ff0000]|[/COLOR][/B]"

 

[Fluff]

@DanteAmor
You're quite right and good spot.