If Statement With Multiple Vlookups

[ericka]

I can't figure out why my result is returning FALSE.

Here's what I'm trying to do: If A1503 equals "System Certified", then perform the vlookup using the value value from cell G1503. If A1503 does not equal System Certified then perform the vlookup on the value in cell AX1503.

Here's my formula:
=IF(A1503="System Certified",VLOOKUP(G1503,'Team Lookup From User Analysis'!$A$2:$C$491,3,IF(A1503<>"System Certified",VLOOKUP(AX1503,'Team Lookup From User Analysis'!$A$2:$C$491,3,FALSE))))

The first part of the formula, before the second if works, I can't figure out why the second part doesn't.

Thanks!

 

[Joe4]

Welcome to the Board! You embedded the second VLOOKUP into the 4th argument of your first VLOOKUP instead of the third argument of your IF statement.
You also don't need the second IF to check to see if it is isn't equal to the first value, as that is implied.

Try:
=IF(A1503="System Certified",VLOOKUP(G1503,'Team Lookup From User Analysis'!$A$2:$C$491,3,FALSE),VLOOKUP(AX1503,'Team Lookup From User Analysis'!$A$2:$C$491,3,FALSE))

 

[ericka]

After putting in the formula, it works with most cells, however I'm coming up with two #N/As because System Certified is not the only value. Is there a way to begin with If A1503 equals "System Certified" or "Not Prepared" or "Rejected", then perform the vlookups?

Thank you!!

 

[Joe4]

After putting in the formula, it works with most cells, however I'm coming up with two #N/As because System Certified is not the only value. Is there a way to begin with If A1503 equals "System Certified" or "Not Prepared" or "Rejected", then perform the vlookups?

Do you mean something like this?
=IF(OR(A1503="System Certified",A1503="Not Prepared",A1503="Rejected"),VLOOKUP(G1503,'Team Lookup From User Analysis'!$A$2:$C$491,3,FALSE),VLOOKUP(AX1503,'Team Lookup From User Analysis'!$A$2:$C$491,3,FALSE))

 

[ericka]

Perfect! That worked!! Thank you!!

 

[Joe4]

You are welcome.

 

[Eric W]

Since parameters 2-4 of the VLOOKUPs are the same, you can write the formula a bit shorter as:

=VLOOKUP(IF(OR(A1503={"System Certified","Not Prepared","Rejected"}),G1503,AX1503),'Team Lookup From User Analysis'!$A$2:$C$491,3,FALSE)