If "red" from a drop-down list in A1, then "certain text" in B1, else a drop-down list in B1. How?

[jkalpus]

If "red" from a drop-down list in A1, then "certain text" in B1, else a drop-down list in B1. How can I do this with VBA?

I want to create a drop-down list in, say A1, which returns RED, GREEN, or BLUE.
If a user selects, say RED in the drop-down list in A1, then I want another text string to be placed in B1, (E.g., "no" in B1).
If a used selects anything else from the drop-down list in A1, then I want another drop-down list in B1.

I'm almost there so any help would be most appreciated. Thanks to all ... jk

 

[mumps]

Copy and paste this macro into the worksheet code module. Do the following: right click the tab for your sheet and click 'View Code'. Paste the macro into the empty code window that opens up. Close the code window to return to your sheet. Make a selection in A1.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("A1")) Is Nothing Then Exit Sub
    If Target = "RED" Then
        With Range("B1")
            .ClearContents
            .Validation.Delete
            .Value = "No"
        End With
    Else
        With Range("B1")
            .ClearContents
            .Validation.Delete
            .Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:="Yes, No"
        End With
    End If
End Sub

 

[jkalpus]

Thanks a LOT, Mumps! Works like a champ!
One follow-up question: INSTEAD of returning "Yes, No" in the drop-down list, how can I reference a NAMED list, say "choices" for the drop-down list?
Many thanks in advance ... jk

 

[mumps]

Created your named range and name it "Choices" then replace this line of code:

 .Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:="Yes, No"

with this line:

 .Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:="=Choices"