IF/MATCH statement that includes the SUM

[Robert_Conklin]

I am in need of an Excel formula that looks to see if cells in column A match. If they do, then provide the sum of all of the cells that match in that group in the first cell of that group in the appropriate column (GA = column "G", "FL" = column "I"). You can see the totals in columns G and I for each group, these are what I need to be auto-summed.

TEST INFO.xlsx
	A	B	C	D	E	F	G	H	I
1	STATE	MILEAGE	TOTAL		FUEL COST	GA	GA FUEL	FL	FL FUEL
2		601549
3	GA	601800	251		$ 200.00	251	251
4	FL	601850	50		$ 600.00			50	1150
5	FL	602900	1050					1050
6	FL	602950	50					50
7	GA	603000	50		$ 420.00	50	350
8	GA	603100	100			100
9	GA	603150	50			50
10	GA	603200	50			50
11	GA	603250	50			50
12	GA	603300	50			50
13	FL	603350	50					50	100
14	FL	603400	50					50
15			-603400			FALSE		FALSE
16			0			FALSE		FALSE
17			0			FALSE		FALSE
18			0			FALSE		FALSE
19			0			FALSE		FALSE
20			0			FALSE		FALSE
21			0			FALSE		FALSE
22			0			FALSE		FALSE
23			0			FALSE		FALSE
24			0			FALSE		FALSE
25			0			FALSE		FALSE
26			0			FALSE		FALSE
27			0			FALSE		FALSE
TEST INFO

Cell Formulas
Range	Formula
C3:C27	C3	=(B3-B2)
F3:F27	F3	=IF(A3="GA",C3,IF(A3="FL",""))
H3:H27	H3	=IF(A3="FL",C3,IF(A3="GA",""))

 

[dermie_72]

C3 can equal =IF(A3="","",B3-B2)
F3 can equal =IF(A3="GA",C3,"")
H3 can equal =IF(A3="FL",C3,"")

If you want totals then
=Sumifs(F:F,A:A,"GA") for GA and =sumifs(H:H,A:A,"FL")
placed where you would like to see them.

 

[Robert_Conklin]

@dermie_72, thank you for the assistance. Yes that formula works great if I need a total sum for ALL of the GA and FL items. What I need is to be able to get the total for the GAs and the FLs for just the small groups that are together. If you look in my example above, row three has a single GA. The total for that line is 251 in column G. The next group has three FLs. The total for that group is 1050 in column I. I need the total to only include the small groups, not the entire total. Is this even possible?

 

[Fluff]

How about in G3 copied down

=IF(AND(A3="ga",A2<>"ga"),SUM(C3:INDEX(C3:C100,XMATCH(TRUE,A3:A100<>"ga")-1)),"")

 

[Robert_Conklin]

@Fluff. That worked perfectly! Thank you very much for your time on this!!

 

[Fluff]

You're welcome & thanks for the feedback.