If cell is blank, copy adjacent cell into blank cell (VBA)

[Mindtriks]

Hi - So I am currently trying to work on some code that will help with the following:

In Column G, I have a bunch of different data points, however some of the cells are blank. If a cell is blank I want it to look at the cell in the adjacent column (Column F) and copy the data from that cell into the empty cell in Column G. I am still new to VBA and any help is greatly appreciated.

 

[hiker95]

In Column G, I have a bunch of different data points

Mindtriks,

1. What is the raw data worksheet name?

2. Are there titles in row 1?

3. Are there formulas in column G?

4. Can we see examples of what is in column G?

5. Can we see examples of what is in column F?

 

[Mindtriks]

Hiker - See Below

1. It is sheet 1, but I will just be using worksheet.activesheet
2. Data starts on row 2, headers are on row 1.
3. No formulas in Column G.
4. Column G is just a list of names.
5. Column F is also a list of names.

Column G and F are populated with names, however when the data is pulled from our database these names can be affiliated with 1 or more different fields. For example, Column G and Column F, both have a name tied to a unique data set, but I need to consolidate those 2 columns.

 

[hiker95]

So I am currently trying to work on some code

Mindtriks,

Can we see all of your current macro code?

When posting VBA code, please use Code Tags - like this:

[code=rich]

'Paste your code here.

[/code]

 

[hiker95]

Re: If cell is blank, copy adjacent cell into blank cell (VBA)
Hiker - See Below

1. It is sheet 1, but I will just be using worksheet.activesheet
2. Data starts on row 2, headers are on row 1.
3. No formulas in Column G.
4. Column G is just a list of names.
5. Column F is also a list of names.

Column G and F are populated with names, however when the data is pulled from our database these names can be affiliated with 1 or more different fields. For example, Column G and Column F, both have a name tied to a unique data set, but I need to consolidate those 2 columns.

Mindtriks,

So that I can get it right on the first try, I would like to see your raw data workbook/worksheet Sheet1.


You can post your workbook/worksheets to the following free site (sensitive data changed), mark the workbook for sharing, and, provide us with a link to your workbook:

Dropbox

 

[My Aswer Is This]

Try this:

Sub Test()
Application.ScreenUpdating = False
Dim c  As Range
    For Each c In Range("G2:G" & Cells(Rows.Count, "G").End(xlUp).Row)
        If c.Value = "" Then c.Value = c.Offset(, -1).Value
    Next
Application.ScreenUpdating = True
End Sub

 

[hiker95]

Mindtriks,

Here is a macro solution for you to consider that does not do any looping thru the rows in the active worksheet in column G, and, should be very fast.

Sub Mindtriks()
' hiker95, 08/22/2017, ME1020002
Application.ScreenUpdating = False
Dim lr As Long
With ActiveSheet
  lr = .Columns("F:G").Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
  On Error Resume Next
  With .Range("G2:G" & lr)
    .SpecialCells(xlCellTypeBlanks).Formula = "=RC[-1]"
    .Value = .Value
  End With
  On Error GoTo 0
End With
Application.ScreenUpdating = True
End Sub

 

[vijkar2008]

Try this:

Sub Test()
Application.ScreenUpdating = False
Dim c  As Range
    For Each c In Range("G2:G" & Cells(Rows.Count, "G").End(xlUp).Row)
        If c.Value = "" Then c.Value = c.Offset(, -1).Value
    Next
Application.ScreenUpdating = True
End Sub

I used the above code for mine and it works magic Thank you!

 

[My Aswer Is This]

I used the above code for mine and it works magic Thank you!

Glad I was able to help you.
Come back here to Mr. Excel next time you need additional assistance.