If and Statement

[sjuhl99]

I have 2 columns of Data, G8 and H8. I am trying to say if G8 > 25% than Supply Review or if H8 > 100% than Demand Review, or if G8 is >25% AND H8 >100% then "Demand and Supply Review", Else "No review Needed" and can't seem to capture the whole formula. Please help




=IF(H8>100%,"Demand Review Needed",IF(G8>25%,"Supply Review Needed",IF(AND(G8>=25%,H8>100%),"Demand and Supply Review")))

 

[mrhstn]

Perhaps try a different order, like this

=IF(AND(G8>=25%,H8>100%),"Demand and Supply Review", IF(G8>25%,"Supply Review Needed", IF(H8>100%,"Demand Review Needed","Neither")))

 

[dms37]

=IF(AND(G8>0.25,H8>1),"Demand and Supply Review",IF(G8>0.25,"Supply Review",IF(H8>1,"Demand Review","No Review Needed")))

 

[sjuhl99]

Got it and it worked thank you both for your help!

 

[mrhstn]

Or perhaps a little boolean logic

=CHOOSE(((G8>25%)+((H8>100%)*2))+1, "No Review", "Supply Review", "Demand Review", "Supply and Demand Review")

 

[sjuhl99]

One more quick question, If I wanted to populate future months with no data, is there an Ifblank addition I need to make so the conditions do not populate?

 

[mrhstn]

Hi

Guessing that in the above you'd be thinking if both G8 and H8 were blank then return nothing, copied down to row 9 for the next month and so on...?

=IF(AND(H8="", G8=""), "", your formula)

 

[sjuhl99]

you got it, thanks again!