Identify Unique names in Column F

[rkol297]

Hello,

I have 4000+ entries that have multiple rows with account names in column F. There are multiple entries for each account throughout the sheet, what I would like to do is keep only one row for each account out of all of the entries so that I can identify how many individual accounts had been reached throughout the year.

Basically keeping only 1 unique account name in Column F out of many account entries.

 

[Fluff]

How about

Sub removedupe()

    Dim cl As Range
    Dim Rng As Range
    
    With CreateObject("scripting.dictionary")
        For Each cl In Range("F2", Range("F" & Rows.Count).End(xlUp))
            If Not .exists(cl.Value) Then
                .Add cl.Value, Nothing
            Else
                If Rng Is Nothing Then
                    Set Rng = cl
                Else
                    Set Rng = Union(Rng, cl)
                End If
            End If
        Next cl
    End With
    Rng.EntireRow.Delete
                
End Sub

This will delete the entire row, for all duplicates. If that is not what you want, let me know

 

[Scott Huish]

If you want VBA:

Sub removeduplicates()
Cells.removeduplicates Columns:=6, Header:=xlYes
End Sub

This can also be done manually, with Remove Duplicates on the Data tab