Ideas on Import & export of excel data

[andrewb90]

Hi everybody!

I am trying to figure out how to export select data and then import it into another sheet. I haven't done much with this kind of stuff, so I'm not even sure what the best way to go about this is:


Multiple users have an identical workbook. The file is fairly large, and I don't want to send the entire workbook through email.
On a weekly basis, they will fill out a sheet, and a section of data from that sheet needs to be exported into some other format. The user will then email that file, and then the recipient will import that file into their workbook.
As all the workbooks will have the same name, a cell value would be used in determining which user's location the data is from.

I'm just not sure what the best avenue to use is going to be.

As far as the cell range goes, that's flexible based on what type of import/export method I'm using, and if there are any particular formats that need to be in place.

Any ideas, links, suggestions, on what may be my best bet would be very much appreciated.

another note, the file doesn't need to be readable or comprehensible, as long as I can run a code to import it, into my workbook correctly. (Not sure if that's even relevant, but i thought I'd mention it)

 

[mole999]

there is code to send a sheet from a book via email, i'll find it and post here. Then all they need to do is select the sheet and run the macro

 

[mole999]

Sub CHUBMail_ActiveSheet()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the ActiveSheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2016
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Part of " & Sourcewb.Name ' & " " & Format(Now, "dd-mmm-yy h-mm-ss")

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .To = "you@there.UK"
            .CC = ""
            .BCC = "me@there.uk"
            .Subject = "CHUB"
            .Body = "Attached is the current CHUB"
            .Attachments.Add Destwb.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
            .Send   'or use .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

 

[andrewb90]

I appreciate the code, however many of the users do not have outlook installed, or are not allowed to use it. Is there any option to just export to the local computer?