I don't want the empty rows in the array, I know why but...

[most]

This script creates a lot of empty rows in the arrays. I understand why, but I don't know how to write the code so it won't, some pointers please.

Sub GroundogDay() Dim i As Integer
 Dim Count As Integer
 Dim ArrDATE(1 To 33) As Variant
 Dim ArrROW(1 To 33) As Variant
  
 For i = 3 To 33
     If Sheets("Feb").Range("A" & i).Value = "Monday" Then
        ArrDATE(i) = Sheets("Feb").Range("B" & i).Value
        ArrROW(i) = Sheets("Feb").Range("A" & i).Row
      Else
     End If
 Next i


        For i = LBound(ArrDATE) To UBound(ArrDATE)
            Debug.Print ArrDATE(i)
        Next i
        For i = LBound(ArrROW) To UBound(ArrROW)
            Debug.Print ArrROW(i)
        Next i
End Sub

 

[Joe4]

If the issue is that the data is blank, then just add an IF statement to your code to check the value before adding it to your array.
You already have an IF statement check to see if Column A is "Monday". Add another IF under that to check to see if column B is not blank.

 

[most]

No, that won't compute. First If statement will already take care of that. I believe the problem is that I have dimension the array to 31 lines from the beginning, (Sorry I didn't point that out from the beginning).

Some clarifications, column A contains all weekdays for a month, the script loops through and should point out row number and the date from column B for all Mondays. Which is does, but it also includes the empty lines.
Maybe there is a better way to do this!?

 

[Joe4]

Sounds like maybe you want to do the following, instead of pre-defining the size of the array before populating it:
https://www.excel-easy.com/vba/examples/dynamic-array.html

 

[Fluff]

Another option

   Dim i As Long, j As Long
   Dim ArrDATE(1 To 33) As Variant
   Dim ArrROW(1 To 33) As Variant
   
   For i = 3 To 33
      If Sheets("Feb").Range("A" & i).Value = "Monday" Then
         j = j + 1
         ArrDATE(j) = Sheets("Feb").Range("B" & i).Value
         ArrROW(j) = Sheets("Feb").Range("A" & i).Row
      End If
   Next i
      ReDim Preserve ArrDATE(1 To j)
      ReDim Preserve ArrROW(1 To j)
   
   For i = LBound(ArrDATE) To UBound(ArrDATE)
      Debug.Print ArrDATE(i)
   Next i
   For i = LBound(ArrROW) To UBound(ArrROW)
      Debug.Print ArrROW(i)
   Next i
End Sub

 

[most]

@Fluff, Excel complaint over "ReDim Preserve ArrDATE(1 To j)", Array already dimensioned.
But with your changes and with some input from Joe4 link I got it to work, THANKS A LOT!

[/COLOR]Sub GroundhogDay()   Dim i As Long, j As Long
   Dim Count As Integer
   Dim Cell As Range
   
    For Each Cell In Range("A3:A33")
     If (Cell.Value = "Monday") Then Count = Count + 1
    Next Cell


      ReDim ArrDATE(1 To Count)
      ReDim ArrROW(1 To Count)


   For i = 3 To 33
      If Sheets("Feb").Range("A" & i).Value = "Monday" Then
         j = j + 1
         ArrDATE(j) = Sheets("Feb").Range("B" & i).Value
         ArrROW(j) = Sheets("Feb").Range("A" & i).Row
      End If
   Next i
    
 Debug.Print "J: "; j
   
   For i = LBound(ArrDATE) To UBound(ArrDATE)
      Debug.Print ArrDATE(i)
   Next i
   For i = LBound(ArrROW) To UBound(ArrROW)
      Debug.Print ArrROW(i)
   Next i
End Sub[COLOR=#333333]

 

[Norie]

Try this.

Dim i As Long, cnt As Long
Dim ArrDATE() As Variant
Dim ArrROW() As Variant
   
   ReDim ArrDATE(1 To 33)
   ReDim ArrROW(1 To 33)
   
   For i = 3 To 33
      If Sheets("Feb").Range("A" & i).Value = "Monday" Then
         cnt = cnt + 1
         ArrDATE(cnt) = Sheets("Feb").Range("B" & i).Value
         ArrROW(cnt) = Sheets("Feb").Range("A" & i).Row
      End If
   Next i
      ReDim Preserve ArrDATE(1 To cnt)
      ReDim Preserve ArrROW(1 To cnt)
   
   For i = LBound(ArrDATE) To UBound(ArrDATE)
      Debug.Print ArrDATE(i)
   Next i
   
   For i = LBound(ArrROW) To UBound(ArrROW)
      Debug.Print ArrROW(i)
   Next i

 

[Fluff]

You can replace the initial loop with

   Dim Cnt  As Long
   Cnt = Application.CountIf(Range("A3:A33"), "Monday")
   ReDim ArrDATE(1 To Cnt)

I would also advise against using VBA keywords (such as Count) as variable names, because it can cause unforeseen problems.