I can't open PDF file after save

[tubrak]

Hello
I suppose this code will create folders current year and month and save file as pdf inside month based on current month , but suddenly shows error message can't open this file !

Sub DateFolderSave()
Application.DisplayAlerts = False
' Check for year folder and create if needed
If Len(Dir("c:\" & Year(Date), vbDirectory)) = 0 Then
 MkDir "c:\" & Year(Date)
End If
' Check for month folder and create if needed
If Len(Dir("c:\" & Year(Date) & "\" & MonthName(Month(Date), False), vbDirectory)) = 0 Then
 MkDir "c:\" & Year(Date) & "\" & MonthName(Month(Date), False)
End If
' Save File
ActiveSheet.SaveAs Filename:= _
"c:\" & Year(Date) & "\" & MonthName(Month(Date), False) & "\" & Format(Date, "mm.dd.yy") & ".PDF" _
, CreateBackup:=False
Application.DisplayAlerts = True
' Popup Message
MsgBox "File Saved As:" & vbNewLine & "c:\" & Year(Date) & _
"\" & MonthName(Month(Date), False) & "\" & Format(Date, "mm.dd.yy") & ".PDF"
End Sub

so what's the problem?

 

[rlv01]

Instead of ActiveSheet.SaveAs, use ActiveSheet.ExportAsFixedFormat:

    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:="c:\" & _
        Year(Date) & "\" & MonthName(Month(Date), False) & "\" & Format(Date, _
        "mm.dd.yy") & ".PDF", Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, IgnorePrintAreas:=False, _
        OpenAfterPublish:=False

 

[OaklandJim]

I hope that this helps.

Option Explicit

Sub DateFolderSave()

    Dim sPath As String
    
    Dim sPathAndFileName As String

    Application.DisplayAlerts = False
    
'   Check for year folder and create if needed
    If Len(Dir("C:\" & Year(Date), vbDirectory)) = 0 _
     Then MkDir "C:\" & Year(Date)
    
'   Check for month folder and create if needed
    If Len(Dir("C:\" & Year(Date) & "\" & MonthName(Month(Date), False), vbDirectory)) = 0 _
     Then MkDir "C:\" & Year(Date) & "\" & MonthName(Month(Date), False)
     
    sPath = "C:\" & Year(Date) & "\" & MonthName(Month(Date)) & "\"
    
    sPathAndFileName = sPath & Format(Date, "mm.dd.yy") & ".PDF"
    
'   Save file as pdf
    ActiveSheet.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=sPathAndFileName, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False      '<= change this to true to open after it is created.
        
    Application.DisplayAlerts = True
    
'   Message to user.
    MsgBox "File Saved As:" & vbNewLine & sPathAndFileName

End Sub

 

[tubrak]

thanks guys !
all of your solutions have fixed my problem .