I can only get this VBA code to work if I add a column onto the end of the dataset.

[dwmlr]

Hello. I'm using this code, but can only seem to get it to work if I add a redundant column at the end of my dataset. In order to to that, I'm referencing column M, but in reality, I'd like to just be able to reference column H. I'm almost positive that it has to do with the offset and resize parameters?

Option Explicit
Sub ExportLogisticsRecords()

Dim StatusCol As Range
Dim Status As Range
Dim PasteCell As Range

Set StatusCol = Sheet1.Range("M2:M10002")

For Each Status In StatusCol

    If Sheet5.Range("A2") = "" Then
        Set PasteCell = Sheet5.Range("A2")
    Else

        Set PasteCell = Sheet5.Range("A1").End(xlDown).Offset(1, 0)
    End If

    If Status Like "*-L" Then Status.Offset(0, -12).Resize(1, 12).Copy PasteCell


Next Status
        
End Sub

 

[kevin9999]

I'm almost positive that it has to do with the offset and resize parameters?

You're right, that's the problem. Rather than fix that, I'd like to suggest the following alternative code for you. Please try it on a copy of your workbook.

Sub Copy_Dash_L()
    If Sheet1.AutoFilterMode Then Sheet1.AutoFilter.ShowAllData
    With Sheet1.Range("A1").CurrentRegion
        .AutoFilter 8, "*-L"
        If .SpecialCells(xlCellTypeVisible).Address <> .Rows(1).Address Then
            .Offset(1).Resize(.Rows.Count - 1).Copy Sheet5.Cells(Rows.Count, 1).End(xlUp).Offset(1)
        End If
        .AutoFilter
    End With
End Sub

 

[dwmlr]

You're right, that's the problem. Rather than fix that, I'd like to suggest the following alternative code for you. Please try it on a copy of your workbook.

Sub Copy_Dash_L()
    If Sheet1.AutoFilterMode Then Sheet1.AutoFilter.ShowAllData
    With Sheet1.Range("A1").CurrentRegion
        .AutoFilter 8, "*-L"
        If .SpecialCells(xlCellTypeVisible).Address <> .Rows(1).Address Then
            .Offset(1).Resize(.Rows.Count - 1).Copy Sheet5.Cells(Rows.Count, 1).End(xlUp).Offset(1)
        End If
        .AutoFilter
    End With
End Sub

That worked great, but it missed two records. I'm going to investigate now. Not to mention that it was soooooo much faster than the code I was using. LOL

Thank you very much Kevin.

 

[kevin9999]

If it missed 2 records then it must be something to do with their value in column H. Possibly a trailing space at the end of their code? If that's the case, change the code to this:

Sub Copy_Dash_L()
    If Sheet1.AutoFilterMode Then Sheet1.AutoFilter.ShowAllData
    With Sheet1.Range("A1").CurrentRegion
        .AutoFilter 8, "*-L*"
        If .SpecialCells(xlCellTypeVisible).Address <> .Rows(1).Address Then
            .Offset(1).Resize(.Rows.Count - 1).Copy Sheet5.Cells(Rows.Count, 1).End(xlUp).Offset(1)
        End If
        .AutoFilter
    End With
End Sub

 

[dwmlr]

If it missed 2 records then it must be something to do with their value in column H. Possibly a trailing space at the end of their code? If that's the case, change the code to this:

Sub Copy_Dash_L()
    If Sheet1.AutoFilterMode Then Sheet1.AutoFilter.ShowAllData
    With Sheet1.Range("A1").CurrentRegion
        .AutoFilter 8, "*-L*"
        If .SpecialCells(xlCellTypeVisible).Address <> .Rows(1).Address Then
            .Offset(1).Resize(.Rows.Count - 1).Copy Sheet5.Cells(Rows.Count, 1).End(xlUp).Offset(1)
        End If
        .AutoFilter
    End With
End Sub

That worked. I've been banging my head against my monitor and a few YouTube channels trying to figure this out. You way is literally 20 times faster.

Thank you so much Kevin.

 

[kevin9999]

Happy to help & thanks for the feedback