How to use find function

[yeat]

Hi, me again.

I want to ask how to use the "FIND" function.

this is my data
model
oppo red
oppo black
apple red

I want to make it to
model
oppo
oppo
apple

this is my formula, but I want multi colors
=LEFT(C7,LEN(C7) - LEN(MID(C7,FIND({"BLACK",C7),999)))
I try this, but not working
=LEFT(C7,LEN(C7) - LEN(MID(C7,FIND({"BLACK","WHITE"},C7),999)))

How to solve this problem, thank you in advance.

 

[Peter_SSs]

Is this what you mean?

22 08 28.xlsm
	C	D
7	model	model
8	oppo red	oppo
9	oppo black	oppo
10	apple red	apple
yeat

Cell Formulas
Range	Formula
D7:D10	D7	=LEFT(C7,AGGREGATE(15,6,SEARCH({" red"," black"," white"},C7&" red"),1)-1)

 

[yeat]

Is this what you mean?

22 08 28.xlsm
	C	D
7	model	model
8	oppo red	oppo
9	oppo black	oppo
10	apple red	apple
yeat

Cell Formulas
Range	Formula
D7:D10	D7	=LEFT(C7,AGGREGATE(15,6,SEARCH({" red"," black"," white"},C7&" red"),1)-1)

wow perfect, but how do you do it? can you explain it?

 

[Peter_SSs]

can you explain it?

The formula adds " red" after the original data so that at least one colour will be found.
SEARCH looks for a space followed by the listed colours. Each will return the position in the string where that is found or an error if the colour is not found.
AGGREAGATE(15,6 ... returns the smallest value from all the searches, (ignoring errors)
LEFT then cuts off the text before that first colour is found

Example with "oppo black"
First add the " red" gives "oppo black red"
SEARCH for " red", " black", " white" gives 11, 5, error
AGGREGATE(15, 6 returns 5
LEFT 1 character less gives "oppo"

 

[yeat]

Got it. thank you very much

 

[Peter_SSs]

You're welcome.