How to unselect an area in a macro

[JenniferMurphy]

The macro below makes a copy of a range of cells just before updating them so I can see the changes. It was leaving the range selected, so I added the last statement, but the range is still left selected (walking dotted border).

How do I cancel the selection?

Sub CopyErrorRow(inRowError As Long, inColLeft As Long, inColRight As Long)
Dim RngErrCurr As String  'The current error stats (source)
Dim RngErrPrev As String  'The previous error stats (destination)
RngErrCurr = Cells(inRowError, inColLeft).Address & ":" & Cells(inRowError, inColRight).Address
RngErrPrev = Cells(inRowError + 1, inColLeft).Address & ":" & Cells(inRowError + 1, inColRight).Address

Range(RngErrCurr).Select
Selection.Copy
Range(RngErrPrev).Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
Selection.PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
Cells(1, 1).Select  'Cancel the selection

End Sub

 

[MARK858]

(walking dotted border).

If you mean take it out of copy mode then...

Application.CutCopyMode = False

 

[JenniferMurphy]

If you mean take it out of copy mode then...

Application.CutCopyMode = False

Yup, that's what I meant to say. I was also about to post that I used the macro recorder to discover the solution that you posted.

Thanks, J

 

[MARK858]

Happy you found a solution, btw I wouldn't use Select/Selection in the code (it only slows it down)....

Sub CopyErrorRow(inRowError As Long, inColLeft As Long, inColRight As Long)
    Dim RngErrCurr As String    'The current error stats (source)
    Dim RngErrPrev As String    'The previous error stats (destination)
    RngErrCurr = Cells(inRowError, inColLeft).Address & ":" & Cells(inRowError, inColRight).Address
    RngErrPrev = Cells(inRowError + 1, inColLeft).Address & ":" & Cells(inRowError + 1, inColRight).Address

    Range(RngErrCurr).Copy
    With Range(RngErrPrev)
        .PasteSpecial Paste:=xlPasteValues, Operation:=xlNone
        .PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone
    Application.CutCopyMode = False
    End With

End Sub

 

[JenniferMurphy]

Thanks for the improved code. My macro is so simple that I can't tell if it's faster, but it's certainly more compact. And, even better, it works!

Cheers