How to trigger a webpage datepicker when doing web scraping?

[S_White]

Hello,

I'm trying to scrape what is known as the ' Yield calculation price' of a listed fixed income instrument. In order to get the right series, I have to set both a from and to date. These can be set by submitting the values to datepickers on the site, but the table underneath with the mentioned price doesn't get updated before either a javascript is called or that the 'toDate' is recognized.

I don't have much experience with how to trigger a javascript and I haven't succeed with pasting the values either. Below, you can see my short code though I would perfer to extract these values by using a XmlHttp request through http://www.nasdaqomxnordic.com/webproxy/DataFeedProxy.aspx but that I cannot figure out either.

Anyone who can take me to the next level?

Sub GetDAta()
Dim IEapp As InternetExplorer, UrlPath As String

UrlPath = "http://www.nasdaqomxnordic.com/bonds/denmark/microsite?Instrument=XCSE5UNIK_A_26"
Set IEapp = New InternetExplorer
With IEapp
    .Navigate UrlPath
    .Visible = True
    Do Until .readyState = READYSTATE_COMPLETE
        DoEvents
    Loop
    With .document
        .getElementById("fromDate").Value = "2019-01-01"
        With .getElementById("toDate")
            .Value = "2019-12-31"
            .Focus
            .Click
        End With
    End With
End With
End Sub

Thanks in advance.

 

[QuietRiot]

If you just need a quick and dirty approach you could use SendKeys "{ENTER}" otherwise it looks like a real pain.

Sub GetData()
    Dim IEapp As Object
    Dim UrlPath As String
      
    Set IEapp = CreateObject("internetexplorer.application")
    IEapp.Visible = True
    
    UrlPath = "http://www.nasdaqomxnordic.com/bonds/denmark/microsite?Instrument=XCSE5UNIK_A_26"
    
    IEapp.navigate (UrlPath)
        
    Do
        DoEvents
    Loop Until IEapp.readystate = 4
    
    If IsObject(IEapp.document.getElementById("fromDate")) Then
        IEapp.document.getElementById("fromDate").Value = "2019-12-31"
        IEapp.document.getElementById("toDate").Value = "2020-06-11"
        IEapp.document.getElementById("toDate").Focus
        SendKeys "{ENTER}"
        IEapp.document.getElementById("nordicSearchBox").Focus
    End If
        
End Sub

 

[S_White]

Never been a big fan of SendKeys and in this case it doesn't work, but thx for the attempt.

 

[QuietRiot]

well then... you owe me one mate! Use IEapp.document.parentWindow.execScript "dbMicrositeFunctions.getHistoryData()"

both sendkeys and running execScript below worked for me..

Sub GetData()
    Dim IEapp As Object
    Dim UrlPath As String
      
    Set IEapp = CreateObject("internetexplorer.application")
    IEapp.Visible = True
    
    UrlPath = "http://www.nasdaqomxnordic.com/bonds/denmark/microsite?Instrument=XCSE5UNIK_A_26"
    
    IEapp.navigate (UrlPath)
        
    Do
        DoEvents
    Loop Until IEapp.readystate = 4
    
    If IsObject(IEapp.document.getElementById("fromDate")) Then
        IEapp.document.getElementById("fromDate").Value = "2019-12-31"
        IEapp.document.getElementById("toDate").Value = "2020-06-11"
        IEapp.document.parentWindow.execScript "dbMicrositeFunctions.getHistoryData()"
    End If
        
End Sub

 

[S_White]

Spot on, @QuietRiot - that did the trick! Rest is just pure reading of rows and cells in the table. Actually, I was looking for a way to trigger the script, but I just couldn't figure out the one I should go for.

Thx - really appreciated - and enjoy the weekend