How to specify range instead of Entire.Row

[feni1388]

Hello everyone....

I'm using this command below to insert a row.
But instead of copying the entire row, I only want to copy from A to Q only.
How should I change the command?

Dim i As Integer
Dim j As Integer

For i = 1 To 10

j = InStr(1, Cells(i, 18), "Freight", vbTextCompare)

If j = 1 Then
Cells(i, 1).EntireRow.Copy

Cells(i + 1, 1).EntireRow.Insert
Application.CutCopyMode = False


Cells(i + 1, 7).Value = "Z001"
Cells(i + 1, 10).Value = Cells(i, 16)

i = i + 1

Else
End If

Next i

Thank you in advance.

 

[Peter_SSs]

First a few comments
When inserting or deleting rows it is usually best to work from the bottom up.
Integer variable values are converted to Long so you might as well declare them that way to start with.
There is no need for your 'Else' line of code since there no code lines in that section.

See how this goes with a copy of your data.

Sub Test()
  Dim i As Long
  Dim j As Long
  
  For i = 10 To 1 Step -1
    j = InStr(1, Cells(i, 18), "Freight", vbTextCompare)
    If j = 1 Then
      Rows(i + 1).Insert
      Cells(i, 1).Resize(, 17).Copy Destination:=Cells(i + 1, 1)
      Cells(i + 1, 7).Value = "Z001"
      Cells(i + 1, 10).Value = Cells(i, 16).Value
    End If
  Next i
End Sub

 

[feni1388]

First a few comments
When inserting or deleting rows it is usually best to work from the bottom up.
Integer variable values are converted to Long so you might as well declare them that way to start with.
There is no need for your 'Else' line of code since there no code lines in that section.

See how this goes with a copy of your data.

Sub Test()
  Dim i As Long
  Dim j As Long
 
  For i = 10 To 1 Step -1
    j = InStr(1, Cells(i, 18), "Freight", vbTextCompare)
    If j = 1 Then
      Rows(i + 1).Insert
      Cells(i, 1).Resize(, 17).Copy Destination:=Cells(i + 1, 1)
      Cells(i + 1, 7).Value = "Z001"
      Cells(i + 1, 10).Value = Cells(i, 16).Value
    End If
  Next i
End Sub

I see....
Thank you for your explanation. I tried the code and it works perfectly well.
Thank you.

 

[Peter_SSs]

You are welcome. Thanks for the follow-up.