How to shade rows alternately in all sheets but two

[Refugar]

Hi!
I have an Excel book with more than 30 sheets. I want to shade rows alternately to blue and white colors, starting on row 6 till the last row containing data, but only applied to columns from A to O and excepting sheets named "Protection" and "Help". Also, I want to know where to place the code.
I need a code from scratch you might suggest or you to correct the ones I show below.

Code 1 to be corrected

Sub TwoColorsForRangeOfRowsAndColumns()
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
 Dim LastRow As Long
 LastRow = Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
 Dim x As Long
   For x = 6 To LastRow Step 2
     Range(Cells(x, 1), Cells(x, 15)).Interior.ColorIndex = 20
     Next x
  For x = 7 To LastRow Step 2
     Range(Cells(x, 1), Cells(x, 15)).Interior.ColorIndex = 2
     Next x
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub

 

[Logit]

Option Explicit

Sub ShadeAlternateRows()
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim cell As Range
    Dim color1 As Long
    Dim color2 As Long
    Dim startRow As Long
    Dim startColumn As String
    Dim endColumn As String

    color1 = RGB(173, 216, 230) ' Light blue color
    color2 = RGB(255, 255, 255) ' White color
    startRow = 6
    startColumn = "A"
    endColumn = "O"

    For Each ws In ThisWorkbook.Sheets
        If ws.Name <> "Protection" And ws.Name <> "Help" Then
            lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
            For i = startRow To lastRow
                If (i - startRow) Mod 2 = 0 Then
                    ws.Range(startColumn & i & ":" & endColumn & i).Interior.Color = color1
                Else
                    ws.Range(startColumn & i & ":" & endColumn & i).Interior.Color = color2
                End If
            Next i
        End If
    Next ws
End Sub

 

[Artik]

And isn't it better to convert the data range to a table and choose the appropriate table formatting?
Using a fixed cell fill will cause a problem when sorting, and also when filtering.

Artik

 

[Peter_SSs]

Welcome to the MrExcel board!

For the future, when posting vba code in the forum, please use the available code tags. It makes your code much easier to read/debug & copy. My signature block at the bottom of this post has more details. I have added the tags for you this time.