how to remove those first 0 in a cell

[newapa]

hi!

i wonder if ther some how i can check if the start of the string is 0 and remove it så it start with a number insted.

somthing like this

016.00123.000
006.00071.000
162.00003.000
012.00065.000
009.00012.000
224.00001.000

to 

16.00123.000
6.00071.000
162.00003.000
12.00065.000
86.00012.000
224.00001.000

thx in advance

 

[Sixthsense]

Assuming that your data start from A1 cell

=--LEFT(A1,FIND(".",A1)-1)&MID(A1,FIND(".",A1),255)

To Avoid error

=IFERROR(--LEFT(A1,FIND(".",A1)-1)&MID(A1,FIND(".",A1),255),A1)

Drag it down

 

[newapa]

hi!

sorry it was bad of me. i didn't type in what i'm searching for. i'm after a macro.
thanx. for the formula. but could u help me with a macro?

thx in advance

 

[Sixthsense]

Try the below code

Sub RemoveLeadingZeros()
Dim LeftVal As Integer, x As Byte, ResulT As String
Dim c As Variant, CkP As Byte

CkP = MsgBox("Have you selected the Range?", _
        vbQuestion + vbYesNo + vbDefaultButton1, "Confirmation About Data Selection")

If CkP = 7 Then Exit Sub

For Each c In Selection
    x = InStr(1, c.Value, ".")
    
    If x Then
        On Error GoTo SkiPLooP
        LeftVal = Left(c.Value, x - 1)
        
        On Error GoTo 0
        ResulT = LeftVal & Mid(c.Value, x, 255)
        c.Value = ResulT
    End If
    
SkiPLooP:

Next c

End Sub

 

[Teeroy]

Another couple of ways to achieve this are:

Sub DeleteLeadingZeros()
Dim reg As Object, cll
Set reg = CreateObject("VBScript.regexp")
With reg
    .Pattern = "^0{0,2}(\d{1,3})"
    For Each cll In ActiveSheet.UsedRange
        cll.Value = .Replace(cll.Value, "$1")
    Next
End With
End Sub

or

Sub DeleteLeadingZeros2()
Dim cll, temp
    For Each cll In ActiveSheet.UsedRange
        temp = Split(cll.Value, ".")
        If IsArray(temp) Then
            temp(LBound(temp)) = Str(Val(temp(LBound(temp))))
            cll.Value = Join(temp, ".")
        End If
    Next
End Sub

 

[Teeroy]

Sorry, stuffed up second example and ran out of edit time. Instead:

Sub DeleteLeadingZeros2()
Dim cll, temp
    For Each cll In ActiveSheet.UsedRange
        If cll.Value <> "" And InStr(cll.Value, ".") Then
            temp = Split(cll.Value, ".")
            temp(LBound(temp)) = Str(Val(temp(LBound(temp))))
            cll.Value = Join(temp, ".")
        End If
    Next
End Sub