How to make textjoin with sum qty?

[Sochen]

Hi everyone,

Could you please help me if find if there is any formula that can combine between "Location of Code" and "Qty" as below.
The result I want is "Summary Location with Qty" in Orange Column.

Thank you!

Test 3.xlsx
	A	B	C	D
1	Location	Code	Qty
2	A1	A001	1
3	B1	A001	2
4	A3	B001	2
5	B1	B001	1
6	A3	B001	2
7	A1	B002	5
8	A3	B002	2
9	A2	C002	1
10	B1	C002	2
11	A3	C003	3
12	B1	C003	1
13	B1	D001	3
14	A3	D001	2
15
16	Code	Qty	Summary Location	Summary Location with Qty
17	A001	3	A1, B1	A1 = 1, B1 = 2
18	B001	5	A3, B1	A3 = 4, B1 = 1
19	B002	7	A1, A3	A1 = 5, A3 = 2
20	C002	3	A2, B1	A2 = 1, B1 = 2
21	C003	4	A3, B1	A3 = 3, B1 = 1
22	D001	5	B1, A3	B1 = 3, A3 = 2
Example 2

Cell Formulas
Range	Formula
A17:A22	A17	=UNIQUE(B2:B14)
B17:B22	B17	=SUMIF($B$2:$B$14,A17,$C$2:$C$14)
C17:C22	C17	=UNIQUE(TEXTJOIN(", ",TRUE,UNIQUE(FILTER($A$2:$A$14,$B$2:$B$14=$A17,""))))
Dynamic array formulas.

 

[Fluff]

How about

=LET(u,UNIQUE(FILTER($A$2:$A$14,$B$2:$B$14=$A17,"")),TEXTJOIN({" = ",", "},TRUE,CHOOSE({1,2},u,SUMIFS($C$2:$C$14,$A$2:$A$14,u,$B$2:$B$14,A17))))

 

[kweaver]

Fluff: you should publish a tutorial on using LET. Always really creative and interesting!!

 

[Sochen]

How about

=LET(u,UNIQUE(FILTER($A$2:$A$14,$B$2:$B$14=$A17,"")),TEXTJOIN({" = ",", "},TRUE,CHOOSE({1,2},u,SUMIFS($C$2:$C$14,$A$2:$A$14,u,$B$2:$B$14,A17))))

It works perfectly. Thank you so much!
What if we use only excel 2019 which this LET function is not available. So may I ask if there is any formula can be used for excel 2019 to solve this problem?

 

[Fluff]

2019 doesn't have the Unique function, so you must be using something newer.

 

[Sochen]

2019 doesn't have the Unique function, so you must be using something newer.

Ok Thank you so much!

 

[Fluff]

You're welcome & thanks for the feedback