How to join text as a date

[kofi11]

Hi,

I have a large dataset where each case reference may have multiple lines. For example showing which staff member made a visit.

I have been asked to join these staff members in a single cell so I use the following formula:

=IF(A2=A1," ",TEXTJOIN(", ",TRUE,OFFSET(P2,0,0,COUNTIF(A:A,A2,1)))

Column A holds all case references. Column P holds the visit staff.

This works fine. But when asked to do the same and join all the visit dates, I just get the 5 digits numbers instead of a string of dd/mm/yyyy dates separed by commas.

The number format is already set to date but the dates still appear as 5 digit numbers.

Can anybody suggest a solution please?

 

[kofi11]

Simplified version of what I'm after shown below on the attached....

 

[etaf]

just use text() infront of whatever you used to join the date
the date is a number , hence why you get that
Text(formula returns the date , "DD/MM/YYYY")
that will change the date to the format you want

whats the visit date formula you have working

TEXT( textjoin(........), "DD/MM/YYYY")

 

[kofi11]

=IF(A2=A1," ",TEXTJOIN(", ",TRUE,OFFSET(P2,0,0,COUNTIF(A:A,A2,1)))

is the formula I have working to join the data.

Works fine except where I want to join dates.

 

[etaf]

sorry put in worng plce
=TEXTJOIN(",",,TEXT(A3:A6,"dd/mm/yyyy"))

Book1
	A	B	C
1
2
3	1/1/24		01/01/2024,02/01/2024,03/01/2024,04/01/2024
4	1/2/24
5	1/3/24
6	1/4/24
Sheet1

Cell Formulas
Range	Formula
C3	C3	=TEXTJOIN(",",,TEXT(A3:A6,"dd/mm/yyyy"))

 

[etaf]

that shjould give an error -
COUNTIF(A:A,A2,1)
not a correct formula

Note: Images are difficult to see , and also requires that I input all the data myself, which means I may make an error, which is very time consuming, and from my point of view less likely to get a response, if a complicated spreadsheet. Plus we cannot see any of the formulas used.

Therefore -

A SMALL sample spreadsheet, around 10-20 rows, would help a lot here, with all sensitive data removed, and expected results mocked up and manually entered, with a few notes of explanation.

This will possibly enable a quicker and more accurate solution for you.

MrExcel has a tool called “XL2BB” that lets you post samples of your data and will allow us to copy/paste your sample data into our Excel spreadsheets, saving a lot of time.

XL2BB - Excel Range to BBCode

Excel 'mini-sheet' in messages - XL2BB Although experts prefer to read your description and question instead of working in your actual file to solve your problem, there are times that it is difficult to explain an issue without providing actual...

www.mrexcel.com

You can also test to see if it works ok, in the "Test Here" forum.

Test Here

Use this forum to test your signature, learn bbcode, smilies, XL2BB, etc. Threads in this forum are automatically deleted after no replies for seven (7) days

www.mrexcel.com

OR if you cannot get XL2BB to work, or have restrictions on your PC

then put the sample spreadsheet onto a share

I only tend to goto OneDrive, Dropbox or google docs , as I'm never certain of other random share sites and possible virus.
Please make sure you have a representative data sample and also that the data has been desensitised, remember this site is open to anyone with internet access to see - so any sensitive / personal data should be removed

Make sure you set any share or google to share to everyone

 

[Fluff]

How about

=IF(A2=A1,"",TEXTJOIN(", ",,TEXT(FILTER($B$2:$B$100,($A$2:$A$100=A2)*($B$2:$B$100<>"")),"dd/mm/yyyy")))

 

[Georgiboy]

Could use ARRAYTOTEXT:

=IF(A2=A1,"",ARRAYTOTEXT(TEXT(FILTER($B$2:$B$18,($A$2:$A$18=A2)*($B$2:$B$18<>""),""),"dd/mm/yyyy")))

Book1
	A	B	C
1	Case	Visit Date	Joined Visit Date
2	4
3	5
4	7
5	8
6	9
7	10
8	11
9	12		19/06/2024
10	12	19/06/2024
11	14
12	17
13	18		19/06/2024, 20/06/2024, 21/06/2024
14	18
15	18	19/06/2024
16	18	20/06/2024
17	18	21/06/2024
18	20
Sheet1

Cell Formulas
Range	Formula
C2:C18	C2	=IF(A2=A1,"",ARRAYTOTEXT(TEXT(FILTER($B$2:$B$18,($A$2:$A$18=A2)*($B$2:$B$18<>""),""),"dd/mm/yyyy")))

 

[kofi11]

Thanks, this works great but I have the added issue of only wanting to add those with the same ref together. See attached

Could use ARRAYTOTEXT:

=IF(A2=A1,"",ARRAYTOTEXT(TEXT(FILTER($B$2:$B$18,($A$2:$A$18=A2)*($B$2:$B$18<>""),""),"dd/mm/yyyy")))

Book1
	A	B	C
1	Case	Visit Date	Joined Visit Date
2	4
3	5
4	7
5	8
6	9
7	10
8	11
9	12		19/06/2024
10	12	19/06/2024
11	14
12	17
13	18		19/06/2024, 20/06/2024, 21/06/2024
14	18
15	18	19/06/2024
16	18	20/06/2024
17	18	21/06/2024
18	20
Sheet1

Cell Formulas
Range	Formula
C2:C18	C2	=IF(A2=A1,"",ARRAYTOTEXT(TEXT(FILTER($B$2:$B$18,($A$2:$A$18=A2)*($B$2:$B$18<>""),""),"dd/mm/yyyy")))

Thank you so much, this is the closest to what I need. Just on your example, for case 18, I would need to show those first visits as blanks (1900).
I've been trying to incorporate that but no luck so far. Any ideas?

 

[Fluff]

In that case try

=IF(A2=A1,"",TEXTJOIN(", ",,TEXT(FILTER($B$2:$B$100,$A$2:$A$100=A2),"dd/mm/yyyy")))