HOW TO GET WORKED HRS FOR SPECIFIC PERIOD

[gssachin]

Hi,



I want to count attendance for a specific period.



I have a 1000 employee’s timesheet. Column “C” to column “AG” for 31 days of May and specific period enter in column “AH” & “AI” i.e. start date & end date



I received attendance in text format to I use to the following formula (in cell “AJ” to get full month attendance.



=(COUNTIF($C$2:$AG$2,"8")*8)+(COUNTIF($C$2:$AG$2,"6")*8)+(COUNTIF($C$2:$AG$2,"5")*5)+(COUNTIF($C$2:$AG$2,"3")*3)



But I need to get attendance for the Specific period only…

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG	AH	AI	AJ
1	EMP NO	NAME	01	02	#	#	#	#	#	#	09	10	11	12	13	14	15	16	17	18	19	20	21	22	23	24	25	26	27	28	29	30	31	START DATE	END DATE	WORKED HRS
2	100	ABC	WO	6	6	6	6	6	6	6	WO	6	6	6	6	6	WO	6	6	6	6	6	6	6	WO	H	H	H	O	O	WO	O	O	10/05/2020	26/05/2020	96
3	101	CDE	6	WO	6	6	6	6	6	6	WO	6	6	6	6	6	6	WO	6	6	6	6	6	6	WO	H	H	H	8	8	8	WO	8	01/05/2020	31/05/2020	184
Sheet1

Cell Formulas
Range	Formula
AJ3	AJ3	=(COUNTIF($C$3:$AG$3,"8")*8)+(COUNTIF($C$3:$AG$3,"6")*8)+(COUNTIF($C$3:$AG$3,"5")*5)+(COUNTIF($C$3:$AG$3,"3")*3)

Any suggestion/help…..

 

[jasonb75]

Try this in J2

edit:- Simpler version, this didn't work when I first tried it, must have had a typo

=SUMPRODUCT(COUNTIFS($C$1:$AG$1,">="&AH2,$C$1:$AG$1,"<="&AI2,C2:AG2,{8,6,5,3}),{8,8,5,3})

 

[gssachin]

Try this in J2

edit:- Simpler version, this didn't work when I first tried it, must have had a typo

=SUMPRODUCT(COUNTIFS($C$1:$AG$1,">="&AH2,$C$1:$AG$1,"<="&AI2,C2:AG2,{8,6,5,3}),{8,8,5,3})

its work for me.... thanks a lot

 

[gssachin]

Hi,

One more help needed if the cell has more than 8 hrs then it should count as 8 hrs Only

 

[jasonb75]

Try this, array confirmed with Ctrl Shift Enter.

=SUMPRODUCT(IFERROR(($C$1:$AG$1>=AH2)*($C$1:$AG$1<=AI2)*TEXT(C2:AG2,"[>=6]\8;[<6]0"),0))

Note that if the formula displays #VALUE! or 0 when a result is expected then it would most likely mean that the array has not been confirmed correctly.

 

[gssachin]

Good Morning,

The above formula works for me but in that formula, I cant specify some text consider as 8 hrs (i.e. if an employee has "SL" - sick leave then it should consider 8 hrs and add it to the total hrs.

Is it possible.....

 

[jasonb75]

Is it only "SL" that needs to be added to the total or are there other text codes to consider as well?
If there are, what are they and what are the hours for each?

 

[gssachin]

No, it's not only "SL", it's changing from time to time like NGP (No gate pass), CR (Due to Corona Leave), ML (Medical leave) it may add a few more.
So like in the 1st formula where we can add text and give how many hrs to add like that I needed.

 

[jasonb75]

Untested

=SUMPRODUCT(IFERROR(($C$1:$AG$1>=AH2)*($C$1:$AG$1<=AI2)*TEXT(SUBSTITUTE(C2:AG2,"SL",8),"[>=6]\8;[<6]0"),0))

Don't forget to array confirm it the same as before.
Here's an example with a second text code so that you can see how to add more if you need to.

=SUMPRODUCT(IFERROR(($C$1:$AG$1>=AH2)*($C$1:$AG$1<=AI2)*TEXT(SUBSTITUTE(SUBSTITUTE(C2:AG2,"NGP",8),"SL",8),"[>=6]\8;[<6]0"),0))

 

[gssachin]

ITS WORK FOR ME THANK YOU