How to detect Userform 'X' or Cancel click from sub that loaded it

[gijimbo]

I have a Sub that loads a userform I created. In the sub, I change a label caption in the form and reuse it using a loop to capture the user's option selection for each new context (but with the same options presented).

Load frmExample

With ActiveSheet
    For x = 1 To UBound(vValue)
        .Cells(inputRow, vValue(x)).Select
        frmExample.lblParameter.Caption = .Cells(inputRow - 1, vValue(x)).Value
        frmExample.Show
        
        'do things depending on which option button was selected
    Next x
End With

I'd like to know how to tell the Sub that the 'X' close button was clicked so it doesn't continue to re-display the Userform.

I know the UserForm_QueryClose() Sub runs when the X is clicked but I don't know how to use that to tell the "calling" Sub that it was clicked. I tried creating a Public boolean variable in the code section for the userform and setting it to True when QueryClose would run but when it would return to the "calling" Sub, the variable wouldn't remain set to True.

 

[DanteAmor]

Try this:

In your Sub:

Public wQuit As Boolean     'at the beginning of all the code


Sub test()
  '
  Load frmExample
  With ActiveSheet
    For x = 1 To UBound(vvalue)
      .Cells(inputRow, vvalue(x)).Select
      frmExample.lblParameter.Caption = .Cells(inputRow - 1, vvalue(x)).Value
      If wQuit = False Then
        frmExample.Show
      Else
        Exit For
      End If
      'do things depending on which option button was selected
    Next x
  End With
End Sub

In your userform:

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
  If CloseMode = 0 Then wQuit = True
End Sub

 

[Mentor82]

Hi
Declare public parameter
Publuc bool_ClosedByControl as boolean (declare it above the sub!)
At the beginning of your sub, before for statement set it to false, bool_ClosedByControl=false
Then, open code of your form, select event on the form called QuerryClose and type in there the following code

If closemode=vbclosecontrolmenu then
   bool_ClosedByControl=true
Else
   bool_ClosedByControl=false
End if

Then, based on the value bool_ClosedByControl you can show or not show the form

If bool_ClosedByControl = false then frmExample.Show

Let me know if that helps you.

 

[gijimbo]

Thanks guys! I was kind of on the right track, I just needed the variable in a higher scope.

For anyone who finds this later, "vbclosecontrolmenu" in Mentor82's post above should actually be "vbFormControlMenu". I certainly don't hold it against him though, I had to look it up here: https://docs.microsoft.com/en-us/office/vba/Language/Reference/User-Interface-Help/queryclose-event

 

[Mentor82]

You're welcome!
You're right I misspelt it, of course, should be vbFormControlMenu

 

[DanteAmor]

Thanks guys!

Youre welcome, thanks for the feedback.