How to close an xlam

[jcarlosd]

I have a mymacros.xlam file that opens automatically when called from file mybook.xlsx, with a ribbon and functions for that specific workbook.
From another VBA code, I close mybook.xlsx, and I want to close also mymacros.xlam.

I read on this thread that it is as simple as running

Workbooks("mymacros.xlam").Close SaveChanges:=False

However, it does not (always) work, because mymacros.xlam is not in the Workbooks collection. Sometimes it correctly close the macro file, sometimes it closes my current workbook, sometimes it crashes.

I tried also to write a macro in mymacros.xlam that closes itself, but again, sometimes it works, sometimes it does not.

I am very confused about this behavior. I googled for a way to close and xlam file but I did not find a solution.

Does anybody have experience with this practice?

J. Carlos

 

[GWteB]

There are different ways to load an AddIn into Excel's memory space, so there are also different ways to unload an AddIn.
The code below should fix your issue.

Sub UnLoadAddin()

    Const cAddIn As String = "AddInName.xlam"          ' <<< change file name to suit

    Dim oAI As Object

    For Each oAI In Application.AddIns
        If StrComp(cAddIn, oAI.Name, vbTextCompare) = 0 Then
            oAI.Installed = False
            Exit Sub
        End If
    Next oAI
    For Each oAI In Application.UsedObjects
        If TypeOf oAI Is Workbook Then
            If StrComp(cAddIn, oAI.Name, vbTextCompare) = 0 Then
                oAI.Saved = True
                oAI.Close
                Exit For
            End If
        End If
    Next oAI
End Sub

 

[Fluff]

How about

Sub DisableAddin()
  AddIns("mymacros").Installed = False
End Sub

 

[GWteB]

@Fluff, whenever a loaded xlam is not located in the default AddIn folder (C:\Users\GWteB\AppData\Roaming\Microsoft\AddIns) or not loaded using Excel's UI (Developer tab > AddIns > browse button) your suggestion will fail.

 

[Fluff]

Wasn't aware of that, thanks.
I've always kept add-ins in the default folder.

 

[GWteB]

I also do that at home, at the office that is not possible in my situation. Also not necessary, especially if several users (without knowing it themselves) use the same AddIn.