how to change the macro - delete many rows

[Paradi]

Hi,

I am asking for help how to change the macro:

Sub Bolts()
With ActiveSheet
.AutoFilterMode = False
With Range("a8", Range("a" & Rows.Count).End(xlUp))
.AutoFilter 1, "*Bolts*"
On Error Resume Next
.Offset(1).SpecialCells(12).EntireRow.Delete
End With
.AutoFilterMode = False
End With
End Sub

This macro finds and removes the specific rows with the word "Bolts"
Can you show me how to change this macro so that macro can also delete rows with many words (such as: cable, radio).

To macro delete rows with words like: "Bolts", "Cable", "radio"

Sorry for my English,. I'm still learning.
Thank You

 

[Fluff]

How about

Sub Bolts()
   Dim Ary As Variant
   Dim i As Long
   
   Ary = Array("*bolts*", "*cable*", "*radio*")
   With ActiveSheet
      .AutoFilterMode = False
      With .Range("a8", .Range("a" & Rows.Count).End(xlUp))
         For i = 0 To UBound(Ary)
            .AutoFilter 1, Ary(i)
            On Error Resume Next
            .Offset(1).SpecialCells(12).EntireRow.Delete
            On Error GoTo 0
         Next i
      End With
      .AutoFilterMode = False
   End With
End Sub

This assumes that you cells contain those words.
If they are the only words in the cell, we can get rid of the loop

 

[paulxmw]

How about

    ActiveSheet.Range("$A$1:$Y$15000").AutoFilter Field:=1, Criteria1:=Array( _
    "Bolts", "radio" "Vable"), Operator:=  xlFilterValues
    Range("A1:I15000").SpecialCells(xlCellTypeVisible).EntireRow.Delete  'This delets the range
    ActiveSheet.ShowAllData

 

[Paradi]

It's working

Thank You .. thank You ...Thank You...

 

[Fluff]

Not sure who your talking to, but glad we could help & thanks for the feedback