How to browse a file txt and import all the info to a excel workbook

[Akihitoc]

Hi good day!
I need help please, I need a macro to be able to select a ".txt" file (using the windows browser) and import all the information on that txt to a new workbook. Then save that new workbook as "BOMNAV" on a file that I choose
Here is what I have so far but Im stuck....

Sub CopyData()
    
    Dim fileDialog As fileDialog
    Dim strPathFile As String
    Dim strFileName As String
    Dim strPath As String
    Dim dialogTitle As String
    Dim wbSource As Workbook
    Dim rngToCopy As Range
    Dim rngRow As Range
    Dim rngDestin As Range
    Dim lngRowsCopied As Long
    
    
    dialogTitle = "Navigate to and select required file."
    Set fileDialog = Application.fileDialog(msoFileDialogFilePicker)
    With fileDialog
        .InitialFileName = "C:\Users\User\Documents"
        '.InitialFileName = ThisWorkbook.Path & "\" 'Alternative to previous line
        .AllowMultiSelect = False
        .Filters.Clear
        .Title = dialogTitle
        
        
        
        If .Show = False Then
            MsgBox "File not selected to import. Process Terminated"
            Exit Sub
        End If
        strPathFile = .SelectedItems(1)
    End With
     
    Set wbSource = Workbooks.Open(Filename:=strPathFile)
    wbkCurrent.Activate
End Sub

 

[lrobbo314]

How about this?

Sub csvImport()
Dim fSel        As FileDialog
Dim wb          As Workbook
Dim ws          As Worksheet


Set wb = Workbooks.Add
Set ws = Sheets("Sheet1")
Set fSel = Application.FileDialog(msoFileDialogFilePicker)
    
With fSel
    .InitialFileName = "C:\Users\User\Documents"
    .AllowMultiSelect = False
    .Filters.Add "Text Files", "*.csv; *.txt"
    .Title = "Navigate ro and select required file."
End With


fSel.Show


With ws.QueryTables.Add(Connection:= _
    "TEXT;" & fSel.SelectedItems(1), _
    Destination:=Range("$A$1"))
    .TextFileCommaDelimiter = True
    .Refresh BackgroundQuery:=False
End With


wb.SaveAs Environ("UserProfile") & "\Desktop\" & "BOMNAV.xlsx"
wb.Close True
End Sub