How to automatically fill text if text in another cell is changed or added

[SunnyAlv]

I am a beginner when it comes to using VBA EXCEL, i hope u can help me

VBA Question

please see image below

I just want to know how to fill the day (TODAY) in each cell in column "A" if :

1. Columns C - F have been filled with text but have changed (in whatever form the essence has changed)

2. every time a new item is added to the last row


***adding the date (TODAY) according to the row the item was changed/new item added


Thank U

 

[kevin9999]

See if the following gives you what you want. As it is worksheet event code, you add it by right-clicking on the sheet tab, select View Code & place the code in the window that appears on the right of the screen. You'll need to save the file as macro-enabled or binary format thereafter.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row > 1 And Not Intersect(Range("C:F"), Target) Is Nothing Then
        Application.EnableEvents = False
        Cells(Target.Row, 1) = Date
        End If
    Application.EnableEvents = True
End Sub

 

[niygint_m]

See if the following gives you what you want. As it is worksheet event code, you add it by right-clicking on the sheet tab, select View Code & place the code in the window that appears on the right of the screen. You'll need to save the file as macro-enabled or binary format thereafter.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row > 1 And Not Intersect(Range("C:F"), Target) Is Nothing Then
        Application.EnableEvents = False
        Cells(Target.Row, 1) = Date
        End If
    Application.EnableEvents = True
End Sub

Chanced upon this thread, and looks useful / similar to my use case.

I'll write down my use case, can you let me know if the above VBA code you provided works? (i believe a few tweaks here and there may be needed...)

I need to autofill cells in column D as 'NZD' once cells in column C are filled in / selected from dropdown menu.

 

[Peter_SSs]

I need to autofill cells in column D as 'NZD' once cells in column C are filled in

Welcome to the MrExcel board!

Try this code instead. It has a bit more built in. If a number is entered in col C then "NZD" will be placed in col D as requested. If a cell in col C has a number deleted, the "NZD" will be removed from col D.
If a number of cells in col C are dealt with at once (eg multiple cells are selected and the values deleted or values entered in multiple cells with Ctrl+Enter or Copy/Paste) then the code will deal with each of the affected rows individually.

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Changed As Range, c As Range
  
  Set Changed = Intersect(Target, Range("C2:C" & Rows.Count))
  If Not Changed Is Nothing Then
    Application.EnableEvents = False
    For Each c In Changed
      If IsNumeric(c.Value) And Len(c.Value) > 0 Then
        c.Offset(, 1).Value = "NZD"
      Else
        c.Offset(, 1).ClearContents
      End If
    Next c
    Application.EnableEvents = True
  End If
End Sub