How to 'append' cells to a spill?

[Rnkhch]

Hello,

I use FILTER to get an output spill of numbers with the needed conditions, as shown in the attached XL2BB, but I was wondering if there is any way I could append the SUM of the spilled cells at the beginning of the spill, followed by the actual spill? In the example, I put the spill in D2 and manually included the SUM in D1

Thanks for any input!

Book1
	A	B	C	D	E
1	188	b		545
2	72	a		72
3	62	c		183
4	92	g		101
5	121	d		189
6	183	a
7	140	t
8	194	f
9	144	h
10	104	s
11	106	d
12	101	a
13	189	a
14	165	f
15	65	v
16
Sheet1

Cell Formulas
Range	Formula
D1	D1	=SUM(FILTER(A1:A15,B1:B15="a"))
D2:D5	D2	=FILTER(A1:A15,B1:B15="a")
Dynamic array formulas.

 

[ISY]

Hi
Excel 365 Beta

=UNIQUE(TOCOL(CHOOSE({1\2},SUM(IF(B1:B15="a",A1:A15)),IF(B1:B15="a",A1:A15,#N/A)),2))

 

[Fluff]

Another option for those not on the beta channel.

Fluff.xlsm
	A	B	C	D	E
1	188	b		545
2	72	a		72
3	62	c		183
4	92	g		101
5	121	d		189
6	183	a
7	140	t
8	194	f
9	144	h
10	104	s
11	106	d
12	101	a
13	189	a
14	165	f
15	65	v
Main

Cell Formulas
Range	Formula
D1:D5	D1	=LET(f,FILTER(A1:A15,B1:B15="a"),r,ROWS(f),s,SEQUENCE(r+1),IF(s=1,SUM(f),INDEX(f,s-1)))
Dynamic array formulas.

 

[Rnkhch]

Thank you guys so much! I'll mark Fluff's version as answer as I don't have TOCOL yet and I don't know when I'll get it

 

[Fluff]

Glad to help & thanks for the feedback.