how select specific range and print out based on selected item from combobox

[Alaa mg]

Hello
I want print out specific range by using name from combobox1 (active x ) inside the sheet(not combobox on userform) ,so when select name from combobox1 then should search for the name in column J and select the range is relating with name based on combobox1 and when click command button1 ,then pop message " do you want print this range " if click ok ,then should print out , if click no ,then should not do any thing .
and if the combobox is empty and click command button1 ,then pop message " do you want print this range " if click ok ,then should print out the whole ranges contains data without any exception , if click no ,then should not do any thing .
example :
when select ALA from combobox1 then just print out H2:I8 and if the combobox1 is empty and click command button1 , then should print out H2:L37

Al (1) (1) (2).xlsm
	H	I	J	K	L
1
2			NAME
3			ALA
4	DATE	Describe	DEBIT	CREDIT	BALANCE
5	05/01/2022	NOT PAID	1,233.00		1,233.00
6	06/01/2022	NOT PAID	1,233.00		2,466.00
7	07/01/2022	PAID		2,000.00	466.00
8	08/01/2022	PAID		466.00	0.00
9
10			NAME
11			ALA1
12	DATE	Describe	DEBIT	CREDIT	BALANCE
13	08/01/2022				0.00
14	09/01/2022	NOT PAID	2,000.00		2,000.00
15	11/01/2022	NOT PAID	2,000.00	1,000.00	3,000.00
16	11/01/2022	NOT PAID	2,000.00	5,000.00	0.00
17
18			NAME
19			ALA2
20	DATE	Describe	DEBIT	CREDIT	BALANCE
21	11/01/2022				0.00
22	12/01/2022	NOT PAID	1,500.00		1,500.00
23	13/01/2022	NOT PAID	500.00		2,000.00
24	14/01/2022	PAID	2,000.00	1,000.00	3,000.00
25	15/01/2022	PAID		1,010.00	1,990.00
26	16/01/2022	PAID		1,000.00	990.00
27	17/01/2022	PAID		990.00	0.00
28
29			NAME
30			ALA
31	DATE	Describe	DEBIT	CREDIT	BALANCE
32	17/01/2022				0.00
33	18/01/2022	NOT PAID	50000		50,000.00
34	19/01/2022	PAID	10000	1,000.00	59,000.00
35	20/01/2022	PAID		2,000.00	57,000.00
36	21/01/2022	PAID		50,000.00	7,000.00
37	22/01/2022	PAID		7,500.00	-500.00
SS

 

[DanteAmor]

Put the following code in a module and run the macro "printname"

Sub printname()
  Dim f As Range
  Dim n As Long
  
  If ActiveSheet.ComboBox1 = "" Then
    Range("H2:L" & Range("H" & Rows.Count).End(3).Row).Select
    Call printselection
  Else
    Set f = Range("J:J").Find(ActiveSheet.ComboBox1.Value, , xlValues, xlWhole, , , False)
    If f Is Nothing Then
      MsgBox "the name does not exist: " & ActiveSheet.ComboBox1.Value
    Else
      n = f.CurrentRegion.Rows.Count
      f.Offset(1, -2).Resize(n - 2, 5).Select
      Call printselection
    End If
  End If
End Sub

Sub printselection()
  Dim res As VbMsgBoxResult

  With ActiveSheet
    res = MsgBox(" do you want print this range ", vbYesNo + vbQuestion)
    If res = vbYes Then
      .PageSetup.PrintArea = Selection.Address
      .PrintOut
    End If
  End With
End Sub

 

[Alaa mg]

it works excellently as I want it .
much appreciated for your assistance.