How do I split a Text with no well defined delimiter

[Abdmujib]

I have some text strings with no well defined delimiter except for the last strings are digit, I want to extract the digits from texts.

Thank you

NB: Excel 2021

 

[RoryA]

Based on that example, something like this:

=-LOOKUP(1,-RIGHT(B2,{1,2,3,4,5,6,7,8,9,10}))

which assumes the numbers are 10 digits or less.

 

[hagia_sofia]

Another option:

=LET(
a,A1,
b,--(MID(a,SEQUENCE(LEN(a)),1)),
c,FILTER(b,ISNUMBER(b)),
--(CONCAT(c)))

 

[Fluff]

How about

=MID(B2,MIN(FIND(SEQUENCE(10,,0),B2&SEQUENCE(10,,0))),100)

 

[Abdmujib]

Thank you @RoryA ,@hagia_sofia and @Fluff all of your solutions works perfectly

 

[Fluff]

Glad we could help & thanks for the feedback.

 

[RoryA]

To answer the question you sent me privately:
Let's assume B2 contains Chalon/Saone8395
The RIGHT(B2,{1,2,3,4,5,6,7,8,9,10}) part of the formula returns an array of the last 1, 2... and so on characters of the text:
5
95
395
8395
e8395
ne8395
one8395
aone8395
Saone8395
/Saone8395

Negating those with - will return either a negative number or an error:

-5
-95
-395
-8395
#VALUE!
#VALUE!
#VALUE!
#VALUE!
#VALUE!
#VALUE!

LOOKUP does two things:
1. It ignores errors, so all those #VALUE! items will simply be ignored.
2. It assumes the data is sorted in ascending order and will return the last value that is less than or equal to the lookup value. Since all the values are negative, they are all less than 1 (which is why using any other positive number will also work). So in this case it returns -8395

The - sign before the LOOKUP then converts that negative number back to a positive: 8395

 

[Abdmujib]

Thank you so much for the explanation