How do I display x,y coordinates without displaying duplicate x,y coordinates?

[arthurz11]

 

[Peter_SSs]

Perhaps for the future you could investigate XL2BB for providing sample data to make it easier for helpers by not having to manually type out sample data to test with?
You will generally get faster & better suggestions.
If you have trouble with XL2BB review the "XL2BB Icons greyed out" link in the 'Known XL2BB issues' section near the top of theXL2BB Instructions page linked above.

See if this does what you want.

24 08 30.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U
1	X	Y	X	Y	X	Y	X	Y	X	Y		X	Y	X	Y	X	Y	X	Y	X	Y
2	2	3	3	3	2	3	1	4	1	4		2	3	3	3	1	4
3	2	1	2	1	1	1	1	2	3	3		2	1	1	1	1	2	3	3
4	2	4	2	3	1	1	3	1	2	3		2	4	2	3	1	1	3	1
5	3	3	3	3	3	3	3	3	3	3		3	3
6	3	1	1	3	4	2	4	1	1	4		3	1	1	3	4	2	4	1	1	4
7	1	2	1	4	2	4	1	2	3	3		1	2	1	4	2	4	3	3
Unique pairs

Cell Formulas
Range	Formula
L2:Q2,L7:S7,L6:U6,L5:M5,L3:S4	L2	=TRANSPOSE(FILTERXML("<p><c>"&SUBSTITUTE(TEXTJOIN("</c><c>",,UNIQUE(FILTERXML("<p><c>"&TEXTJOIN({"|","</c><c>"},,A2:J2)&"</c></p>","//c"))),"|","</c><c>")&"</c></p>","//c"))
Dynamic array formulas.

 

[arthurz11]

Whoa! The complexity of the formula is way too difficult for me to understand as much as me trying to explain it to someone else. Can we just simplify it by just doing one row instead of all four rows? Would you please be so kind as to just do one row where it does not display duplicate x,y coordinates. I will be greatly appreciated.

 

[Peter_SSs]

Whoa! The complexity of the formula is way too difficult for me

It is not a simple task with your excel version (or any version for that matter)

Can we just simplify it by just doing one row instead of all four rows?

The formula is for one row. It needs to be copied down from L2 to the other cells in column L if you want the results for multiple rows.
Here it is (again) for one row.
Somebody else might have a simpler way but it was the best I could come up with by formula.
It could be done by vba as an alternative, but that has its own complexities.

24 08 30.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U
1	X	Y	X	Y	X	Y	X	Y	X	Y		X	Y	X	Y	X	Y	X	Y	X	Y
2	2	3	3	3	2	3	1	4	1	4		2	3	3	3	1	4
Unique pairs

Cell Formulas
Range	Formula
L2:Q2	L2	=TRANSPOSE(FILTERXML("<p><c>"&SUBSTITUTE(TEXTJOIN("</c><c>",,UNIQUE(FILTERXML("<p><c>"&TEXTJOIN({"|","</c><c>"},,A2:J2)&"</c></p>","//c"))),"|","</c><c>")&"</c></p>","//c"))
Dynamic array formulas.

 

[RoryA]

I don't know if it's any better but:

=TEXTSPLIT(TEXTJOIN(",",,(UNIQUE(TEXTSPLIT(TEXTJOIN({",",";"},TRUE,A2:J2),,";")))),",")

 

[arthurz11]

I don't know if it's any better but:

=TEXTSPLIT(TEXTJOIN(",",,(UNIQUE(TEXTSPLIT(TEXTJOIN({",",";"},TRUE,A2:J2),,";")))),",")

The results was #NAME?. I doubled checked the formula but I got the same. Please help.

 

[Peter_SSs]

I don't know if it's any better but:

=TEXTSPLIT(TEXTJOIN(",",,(UNIQUE(TEXTSPLIT(TEXTJOIN({",",";"},TRUE,A2:J2),,";")))),",")

OP has 2021 which doesn't have TEXTSPLIT as far as I am aware.

 

[Fluff]

Another option, although not necessarily simpler

=LET(f,FILTER(A2:J2,A2:J2<>""),s,SEQUENCE(COLUMNS(f)/2,,0),u,UNIQUE(INDEX(f,,s*2+{1,2})),ss,SEQUENCE(COUNT(u),,0),TRANSPOSE(INDEX(u,INT(ss/2)+1,MOD(ss,2)+1)))

 

[RoryA]

OP has 2021 which doesn't have TEXTSPLIT as far as I am aware

Shows I'm getting old - I thought they came in at the same time!

 

[arthurz11]

Another option, although not necessarily simpler

=LET(f,FILTER(A2:J2,A2:J2<>""),s,SEQUENCE(COLUMNS(f)/2,,0),u,UNIQUE(INDEX(f,,s*2+{1,2})),ss,SEQUENCE(COUNT(u),,0),TRANSPOSE(INDEX(u,INT(ss/2)+1,MOD(ss,2)+1)))

Works great!!!!! You da Man! The Myth, and the Legend. I appreciated all your help.