how do i change the series names in my chart

[Boogerbut74]

Right now my series names are from F10 to T10. and i have that in my data set but its just putting each series as series 1 to series 16.

Sub Test_6()


Dim lastrow As Integer
lastrow = Cells(Rows.Count, 10).End(xlUp).Row

'setting x and y axis
Set yData = ActiveSheet.Range("F11:t" & lastrow)
Set xData = ActiveSheet.Range("D11:D" & lastrow)
Set GraphRange = Union(xData, yData)

'Create a chart
   Set cht = ActiveSheet.ChartObjects.Add( _
    Left:=ActiveCell.Left, _
    Width:=450, _
    Top:=ActiveCell.Top, _
    Height:=250)





'Give chart some data
  cht.Chart.SetSourceData Source:=GraphRange


'Determine the chart type
cht.Chart.ChartType = xlXYScatterSmooth
 'edits chart detailes
cht.Chart.Axes(xlCategory).MinimumScale = 0
cht.Chart.Axes(xlCategory).MaximumScale = 100

cht.Chart.Axes(xlValue).MinimumScale = 115
cht.Chart.Axes(xlValue).MaximumScale = 140

cht.Chart.Legend.Position = xlLegendPositionBottom
 
  
End Sub

 

[rlv01]

Right now my series names are from F10 to T10. and i have that in my data set

Your data set, as defined by your code, starts on row 11, so it's not in your data set. Since you are not using xData or yData, you can simplify (tested on my data)

Sub Test_6()
    
    Dim lastrow As Integer
    Dim GraphRange As Range
    
    lastrow = ActiveSheet.Cells(ActiveSheet.Rows.Count, 10).End(xlUp).Row
    
    'set chart data range (including series names)
    Set GraphRange = ActiveSheet.Range("D10:T" & lastrow)
    
    'Create a chart
    Set cht = ActiveSheet.ChartObjects.Add( _
    Left:=ActiveCell.Left, _
    Width:=450, _
    Top:=ActiveCell.Top, _
    Height:=250)
    
    'Give chart some data
    cht.Chart.SetSourceData Source:=GraphRange
    
    'Determine the chart type
    cht.Chart.ChartType = xlXYScatterSmooth
    'edits chart detailes
    cht.Chart.Axes(xlCategory).MinimumScale = 0
    cht.Chart.Axes(xlCategory).MaximumScale = 100
    
    cht.Chart.Axes(xlValue).MinimumScale = 115
    cht.Chart.Axes(xlValue).MaximumScale = 140
    
    cht.Chart.Legend.Position = xlLegendPositionBottom
End Sub