How can I fix #VALUE! error

[Sean15]

Please see minsheet below.
The intent is when value in F is 0.00, the row below (from A to F) should return empty cells. (see A73 to F73)
But Excel is returning #VALUE! in C74 to F74 and C75 to F75.
Could you help with a fix?

mortgage calculator.xlsx
	A	B	C	D	E	F
71	5/1/2027	65	236.92	0.94	235.98	236.45
72	6/1/2027	66	236.92	0.47	236.45	0.00
73
74			#VALUE!	#VALUE!	#VALUE!	#VALUE!
75			#VALUE!	#VALUE!	#VALUE!	#VALUE!
Sheet1

Cell Formulas
Range	Formula
A71:A75	A71	=IF(B71>$B$4,"",IF(B71="","",DATE(YEAR(A70),MONTH(A70)+1,DAY(A70))))
B71:B75	B71	=IF(B70>=$B$4,"",IF(B70="","",B70+1))
C71:C72	C71	=IF(F70=0,"",C70)
D71:D72	D71	=IF(F70=0,"",IPMT($B$3/12,1,$B$4,F70,0)*-1)
E74:E75,E71:E72	E71	=IF(F70=0,"",C71-D71)
F71	F71	=ROUND(F70-E71,2)
F72,F74:F75	F72	=F71-E72
C73,C75	C73	=IF(ROUND(F72,2)=0,"",C72)
D73:D75	D73	=IF(ROUND(F72,2)=0,"",IPMT($B$3/12,1,$B$4,F72,0)*-1)
E73	E73	=IF(ROUND(F72,2)=0,"",C73-D73)
F73	F73	=IF(ROUND(F72,2)=0,"",F72-E73)
C74	C74	=IF(ROUND(F73,2)=0,"",IF(F73="","",C73))

 

[bebo021999]

To turn #VALUE from a formula into "", try:
=IFERROR(formula,"")

For ex, C74:
=IFERROR(IF(ROUND(F73,2)=0,"",IF(F73="","",C73)),"")

 

[breynolds0431]

Please see minsheet below.
The intent is when value in F is 0.00, the row below (from A to F) should return empty cells. (see A73 to F73)
But Excel is returning #VALUE! in C74 to F74 and C75 to F75.
Could you help with a fix?

mortgage calculator.xlsx
	A	B	C	D	E	F
71	5/1/2027	65	236.92	0.94	235.98	236.45
72	6/1/2027	66	236.92	0.47	236.45	0.00
73
74			#VALUE!	#VALUE!	#VALUE!	#VALUE!
75			#VALUE!	#VALUE!	#VALUE!	#VALUE!
Sheet1

Cell Formulas
Range	Formula
A71:A75	A71	=IF(B71>$B$4,"",IF(B71="","",DATE(YEAR(A70),MONTH(A70)+1,DAY(A70))))
B71:B75	B71	=IF(B70>=$B$4,"",IF(B70="","",B70+1))
C71:C72	C71	=IF(F70=0,"",C70)
D71:D72	D71	=IF(F70=0,"",IPMT($B$3/12,1,$B$4,F70,0)*-1)
E74:E75,E71:E72	E71	=IF(F70=0,"",C71-D71)
F71	F71	=ROUND(F70-E71,2)
F72,F74:F75	F72	=F71-E72
C73,C75	C73	=IF(ROUND(F72,2)=0,"",C72)
D73:D75	D73	=IF(ROUND(F72,2)=0,"",IPMT($B$3/12,1,$B$4,F72,0)*-1)
E73	E73	=IF(ROUND(F72,2)=0,"",C73-D73)
F73	F73	=IF(ROUND(F72,2)=0,"",F72-E73)
C74	C74	=IF(ROUND(F73,2)=0,"",IF(F73="","",C73))

I would start with the IF Blank part in your formulas. For example:

Instead of:

=IF(ROUND(F73,2)=0,"",IF(F73="","",C73))

Use:

=IF(F73="","",IF(ROUND(F73,2)=0,"",C73))

 

[Sean15]

Thank you so much.