How can I exclude subfolders in a subfolder

[Ascherith]

Hello!

I am new here and I hope you can help me as I am a noob when in comes to macros.

I have a macro that I want to create that can list down all the file name and the file path of each item inside a folder.
I also want this macro to list the items inside a subfolder. Note that there is also a subfolder inside the subfolder but I don't want to list down the files on the deeper subfolders.
Please see the screenshots below.
When I choose the folder name " Folder to Check", what I need is for the macro to run through all the sub folders "1 to 5" listing down all the PDF file names but will not include the PDF files inside the subfolder ABC.
Please note that these are just sample folder names but it is basically the logic of it. Some subfolders have multiple subfolders inside which I want to exclude with out specifying their names. Is this possible? Can you please edit the below code if it can be done on that? Thank you very much and I would really appreciate it!

For Each oSubfolder In oFolder.SubFolders
queue.Add oSubfolder
Next oSubfolder

 

[John_w]

When I choose the folder name " Folder to Check", what I need is for the macro to run through all the sub folders "1 to 5" listing down all the PDF file names but will not include the PDF files inside the subfolder ABC.
Please note that these are just sample folder names but it is basically the logic of it. Some subfolders have multiple subfolders inside which I want to exclude with out specifying their names.

There's no need for the code to exclude the subfolders of the first level subfolders by their names. You want to list the PDF files in just the first level subfolders of the chosen "Folders to check" folder, so the code below simply loops through the subfolders and has a nested loop to loop through the files in each subfolder.

Public Sub List_PDF_Files_In_First_Level_Subfolders()

    Dim startFolderPath As String
    Dim startCell As Range, n As Long
    Dim FDfolder As FileDialog
    Dim FSO As Object 'Scripting.FileSystemObject
    Dim FSsubfolder As Object 'Scripting.Folder
    Dim FSfile As Object 'Scripting.File
    
    Set FDfolder = Application.FileDialog(msoFileDialogFolderPicker)
    
    With FDfolder
        .Title = "Select Folder"
        If Not .Show Then
            MsgBox "User cancelled", vbInformation
            Exit Sub
        End If
        startFolderPath = .SelectedItems(1)
    End With
    
    With ThisWorkbook.Worksheets(1)
        .Activate
        .Cells.Clear
        .Range("A1").Value = "Path"
        Set startCell = .Range("A2")
    End With
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    n = 0
    For Each FSsubfolder In FSO.GetFolder(startFolderPath).SubFolders
        For Each FSfile In FSsubfolder.Files
            If FSfile.Name Like "*.pdf" Then
                startCell.Offset(n).Value = FSfile.Path
                n = n + 1
            End If
        Next
    Next
        
End Sub

 

[Ascherith]

There's no need for the code to exclude the subfolders of the first level subfolders by their names. You want to list the PDF files in just the first level subfolders of the chosen "Folders to check" folder, so the code below simply loops through the subfolders and has a nested loop to loop through the files in each subfolder.

Public Sub List_PDF_Files_In_First_Level_Subfolders()

    Dim startFolderPath As String
    Dim startCell As Range, n As Long
    Dim FDfolder As FileDialog
    Dim FSO As Object 'Scripting.FileSystemObject
    Dim FSsubfolder As Object 'Scripting.Folder
    Dim FSfile As Object 'Scripting.File
   
    Set FDfolder = Application.FileDialog(msoFileDialogFolderPicker)
   
    With FDfolder
        .Title = "Select Folder"
        If Not .Show Then
            MsgBox "User cancelled", vbInformation
            Exit Sub
        End If
        startFolderPath = .SelectedItems(1)
    End With
   
    With ThisWorkbook.Worksheets(1)
        .Activate
        .Cells.Clear
        .Range("A1").Value = "Path"
        Set startCell = .Range("A2")
    End With
   
    Set FSO = CreateObject("Scripting.FileSystemObject")
   
    n = 0
    For Each FSsubfolder In FSO.GetFolder(startFolderPath).SubFolders
        For Each FSfile In FSsubfolder.Files
            If FSfile.Name Like "*.pdf" Then
                startCell.Offset(n).Value = FSfile.Path
                n = n + 1
            End If
        Next
    Next
       
End Sub

Hi! Thank you very much! I added a separate column for the file name of the PDF and some alignments. Works perfectly!

 

[Ascherith]

Hello, I have another question regarding the file type. What is the syntax if I want the macro to read only pdf files both upper and lowercase? Because my current macro is only reading the lowercase pdf. Thank you.

For Each FSsubfolder In FSO.GetFolder(startFolderPath).SubFolders
        For Each FSfile In FSsubfolder.Files
            If FSfile.Name Like "*.pdf" Then
                startCell.Offset(n).Value = FSfile.Path

 

[John_w]

What is the syntax if I want the macro to read only pdf files both upper and lowercase?

If LCase(FSfile.Name) Like "*.pdf" Then

 

[Ascherith]

If LCase(FSfile.Name) Like "*.pdf" Then

Thank you once again! You're a great help!