Highlight ROW (Range A:L) through VBA

[ARUNCHENNAI]

I want to highlight the duplicate row & strike the contents.
What to modify in the below code, to get the result

Dim ma As Workbook
Dim mas As Worksheet

Sub test()
Application.ScreenUpdating = False
Application.DisplayAlerts = False

'Set Master File
Set ma = ThisWorkbook
Set mas = ma.Worksheets("Master_Dept")

Dim myrng, mycel, c_rng As Range
Set myrng = mas.Range("G8:G500")
 For Each mycel In myrng
  If WorksheetFunction.CountIf(myrng, mycel.Value) > 1 Then
   mycel.Interior.ColorIndex = 3
  End If
 Next mycel

End Sub

Thanks in advance.

Arun

 

[Momentman]

Is this what you require?

Sub test()
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    
    Dim ma As Workbook
    Dim mas As Worksheet
    
    Set ma = ThisWorkbook
    Set mas = ma.Worksheets("Master_Dept")
    
    Dim myrng, mycel As Range, c_rng As Range
    Set myrng = mas.Range("G8:G500")
    For Each mycel In myrng
        If WorksheetFunction.CountIf(myrng, mycel.Value) > 1 Then
            With Rows(mycel.Row)
                .Interior.ColorIndex = 3
                .Font.Strikethrough = True
            End With
        End If
    Next mycel


    Application.ScreenUpdating = True
    Application.DisplayAlerts = True


End Sub

 

[ARUNCHENNAI]

Thank you MomentMan.
Working perfectly.

Regards
Arun

 

[Peter_SSs]

@ARUNCHENNAI

Two questions:

1. Are you aware that this result could be achieved with Excel's built-in Conditional Formatting without vba?

2. Are you aware that the following line of code only declares c_rng as Range and that the other two variables will be Variant type?

Dim myrng, mycel, c_rng As Range

If you want to declare them all as Range variables, you need to specify for each one:

Dim myrng as Range, mycel as Range, c_rng As Range

 

[ARUNCHENNAI]

Peter_SSs. Thank you very much.

1. Yes, I'm aware of conditional formatting without vba.
2. This is new to me. I learned new information. Thank you so much.
In future, will correct my coding.

 

[Peter_SSs]

Glad to contribute.