Hiding columns when other columns become visible

[Godot60]

I have written some code to make some columns visible based on a click of a button. I'd like to make it so when these columns appear (L & M) three other columns are hidden (I, J, and K). Any suggestions would be welcome. Thanks!

Sub Hide()
Sheets("Increase Program Workbook").Unprotect Password:="Password"
With Columns("L:M")
If .EntireColumn.Hidden = True Then
.EntireColumn.Hidden = False
Else
.EntireColumn.Hidden = True
End If
Sheets("Increase Program Workbook").Protect Password:="Password"
End With


End Sub

 

[Fluff]

How about

Sub Hide()
   With Sheets("Increase Program Workbook")
      .Unprotect Password:="Password"
      With .Columns("L:M")
         .EntireColumn.Hidden = Not .EntireColumn.Hidden
         .Columns("I:K").EntireColumn.Hidden = Not .EntireColumn.Hidden
      End With
      .Protect Password:="Password"
   End With
End Sub

 

[Godot60]

I tried this and it hides and unhides L and M but does nothing to I, J, and K.

 

[Joe4]

I wonder if Fluff's code is trying to do too much at once. Maybe this modification will work:

Sub Hide()   Dim hc As Boolean
   With Sheets("Increase Program Workbook")
      .Unprotect Password:="Password"
      With .Columns("L:M")
         hc = .EntireColumn.Hidden
         .EntireColumn.Hidden = Not hc
         Columns("I:K").EntireColumn.Hidden = hc
      End With
      .Protect Password:="Password"
   End With
End Sub

 

[Joe4]

Actually, Fluff's original code will work with one minor edit.
Change this line:

.Columns("I:K").EntireColumn.Hidden = Not .EntireColumn.Hidden

to this:

Columns("I:K").EntireColumn.Hidden = Not .EntireColumn.Hidden

That leading period makes all the difference, between columns I:K are not contained within the range L:M.

 

[Fluff]

Good spot Joe
@Godot60
You may find that cols T:V are hidden, due to my mistake of putting the period before Columns("I:K")

 

[Godot60]

Thanks to both of you for your help! Works great!

 

[Fluff]

Glad we could help & thanks for the feedback