Hiding and revealing the sheet with the sheet list

[mmn1000]

Hello
In an Excel file that has several sheets, there is a ComboBox in each of the sheets.
I created a sheet list with the code below

Private Sub Worksheet_Activate()
ComboBox1.Clear
 
For wsheet = 1 To Sheets.Count
   ComboBox1.AddItem Sheets(wsheet).Name
Next
 
End Sub

By selecting the name of the sheet from the ComboBox, we go to the desired sheet

Private Sub ComboBox1_Change()

 If Not ComboBox1.Text = "" Then
    Sheets(ComboBox1.Text).Select
 End If

 End Sub

How can I hide other sheets by selecting the name of the sheet and going to the desired sheet?
For this, I used the following code, but it did not work correctly

Private Sub ComboBox1_Change()
Sheets("Sheet1").Select
ActiveWindow.SelectedSheets.Visible = False
 
    If Not ComboBox1.Text = "" Then
       Sheets(ComboBox1.Text).Visible = True
       Sheets(ComboBox1.Text).Select
   End If

End Sub

Please help me how to do this

 

[bebo021999]

How about?

Private Sub ComboBox1_Change()
Dim ws As Worksheet
If ComboBox1.Text = "" Then Exit Sub ' Do nothing if select "blank"

' Hide all sheets except the desired sheet
For Each ws In ThisWorkbook.Sheets
    If ws.Name <> ComboBox1.Text Then
        ws.Visible = xlSheetHidden
    End If
Next ws

' Show and select the desired sheet
 With Sheets(ComboBox1.Text)
        .Visible = xlSheetVisible
        .Select
End With
End Sub

 

[mmn1000]

How about?

Private Sub ComboBox1_Change()
Dim ws As Worksheet
If ComboBox1.Text = "" Then Exit Sub ' Do nothing if select "blank"

' Hide all sheets except the desired sheet
For Each ws In ThisWorkbook.Sheets
    If ws.Name <> ComboBox1.Text Then
        ws.Visible = xlSheetHidden
    End If
Next ws

' Show and select the desired sheet
 With Sheets(ComboBox1.Text)
        .Visible = xlSheetVisible
        .Select
End With
End Sub

Thank you for your guide
Your code worked correctly in the first step, by selecting the desired sheet, it was moved to it and other sheets were hidden
But when we try to move to another sheet, we encounter the following error and the program gives an error

Microsoft Visual Basic

Run-time error '1004':
Method 'Visible' of object '_Worksheet' failed

 

[bebo021999]

Maybe:

ws.Hidden = True

 

[Georgiboy]

It may be becuase when the code is run the second time and the combobox value has changed it will be trying to hide all of the sheets in the workbook which can't be done. Try swapping the two code blocks around so it makes the desired tab visible before it hides the ones that are not needed.

 

[mmn1000]

It may be becuase when the code is run the second time and the combobox value has changed it will be trying to hide all of the sheets in the workbook which can't be done. Try swapping the two code blocks around so it makes the desired tab visible before it hides the ones that are not needed.

Can you help me with more examples?

 

[mmn1000]

Maybe:

ws.Hidden = True

It gave an error message again

 

[Georgiboy]

Can you help me with more examples?

Just swapping the two blocks of code:

Private Sub ComboBox1_Change()
    Dim ws As Worksheet
    If ComboBox1.Text = "" Then Exit Sub ' Do nothing if select "blank"
    
    ' Show and select the desired sheet
    With Sheets(ComboBox1.Text)
            .Visible = xlSheetVisible
            .Select
    End With
    
    ' Hide all sheets except the desired sheet
    For Each ws In ThisWorkbook.Sheets
        If ws.Name <> ComboBox1.Text Then
            ws.Visible = xlSheetHidden
        End If
    Next ws
End Sub

 

[mmn1000]

Just swapping the two blocks of code:

Private Sub ComboBox1_Change()
    Dim ws As Worksheet
    If ComboBox1.Text = "" Then Exit Sub ' Do nothing if select "blank"
   
    ' Show and select the desired sheet
    With Sheets(ComboBox1.Text)
            .Visible = xlSheetVisible
            .Select
    End With
   
    ' Hide all sheets except the desired sheet
    For Each ws In ThisWorkbook.Sheets
        If ws.Name <> ComboBox1.Text Then
            ws.Visible = xlSheetHidden
        End If
    Next ws
End Sub

Thank you for your beautiful answer