Hide ribbon

[Sharid]

I am using the following to hide the ribbon and tabs/scrollbars. Although it works fine. I am still having some issues with it, if the workbook is minimised or reduce in size then the top half of the code fails and the ribbion and formula bar are no longer hidden

Private Sub Workbook_Open()
        Application.DisplayFullScreen = True
        Application.CommandBars("Full Screen").Visible = False
        Application.CommandBars("Worksheet Menu Bar").Enabled = False

        ActiveWindow.DisplayGridlines = False
        ActiveWindow.DisplayHeadings = False
       Application.DisplayFormulaBar = False
       Application.DisplayTabBar = False
       ActiveWindow.DisplayWorkbookTabs = False
       ActiveWindow.DisplayHorizontalScrollBar = False
       ActiveWindow.DisplayVerticalScrollBar = False
Worksheets("Sheet1").Activate
 End With

End Sub

 

[Jaafar Tribak]

Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",FALSE)"

 

[Sharid]

Jaafar

Your code seems to work on its own, but not with my code added. I am trying to hide everything. This includes the

• Sheet Tabs
• Formula Bar
• Both Scroll Bars
• Status Bar at the Bottom

Before - on work book open

After - When minimised or workbook reduced in size

Current Code

Private Sub Workbook_Open()
    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",FALSE)"
    Application.DisplayFullScreen = True
    Application.CommandBars("Full Screen").Visible = False
    Application.CommandBars("Worksheet Menu Bar").Enabled = False
    ActiveWindow.DisplayGridlines = False
    ActiveWindow.DisplayHeadings = False
    Application.DisplayFormulaBar = False
    ActiveWindow.DisplayWorkbookTabs = False
    ActiveWindow.DisplayHorizontalScrollBar = False
    ActiveWindow.DisplayVerticalScrollBar = False 

Worksheets("Sheet1").Activate
End Sub

Also will this work on All excels

  Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",FALSE)"

Thanks

 

[Jaafar Tribak]

Also will this work on All excels

Do you mean you want to hide everything on ALL currently open excel windows at the same time or you want to hide things ONLY on the current workbook window ?

 

[Sharid]

Sorry Jaafar when I asked about "Will this work with all excels" I was refering to the different excel versions like 2007, 2010, and so on.

As for hiding everything, it is only for the workbook that the code is in. See attached demo for what I am trying to achive

Download Demo File

Also is it possible to hide the cell selections,

Hope this helps. Thanks

 

[Jaafar Tribak]

Place this in the ThisWorkbook Module and see if OK :

Option Explicit

Private Sub Workbook_Activate()
    Call FullView(True)
End Sub

Private Sub Workbook_Deactivate()
    Call FullView(False)
End Sub

Private Sub Workbook_WindowResize(ByVal Wn As Window)
    With Application
        .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",FALSE)"
        .DisplayFormulaBar = False
    End With
End Sub

Private Sub FullView(ByVal bFullView As Boolean)
    With Application
        .ExecuteExcel4Macro ("SHOW.TOOLBAR(""Ribbon""," & CBool(Not bFullView) & ")")
        .DisplayFullScreen = bFullView
        .CommandBars("Full Screen").Visible = Not bFullView
        .CommandBars("Worksheet Menu Bar").Enabled = Not bFullView
        .DisplayFormulaBar = Not bFullView
        .ActiveWindow.DisplayGridlines = Not bFullView
        .ActiveWindow.DisplayHeadings = Not bFullView
        .ActiveWindow.DisplayWorkbookTabs = Not bFullView
        .ActiveWindow.DisplayHorizontalScrollBar = Not bFullView
        .ActiveWindow.DisplayVerticalScrollBar = Not bFullView
    End With
End Sub

 

[Sharid]

Jaafar this is super,

Only one issue the bottom status bar reapears after workbook is minimised, any chance this can also stay hidden.

 

[Sharid]

It ok I have done it, Just added this

Private Sub Workbook_WindowResize(ByVal Wn As Window)
    With Application
        .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",FALSE)"
        .DisplayFormulaBar = False
        .DisplayStatusBar = False ''' Added This
    End With
End Sub

 

[kamranyd]

i tried these codes, very good but how you bring back everything, i mean back to normal sheet with all tabs

 

[Jaafar Tribak]

i tried these codes, very good but how you bring back everything, i mean back to normal sheet with all tabs

Call FullView(False)