Hide multiple sheets, simplify the code [VBA]

[Martin_H]

Hi,

would it be possible to simplify & speed up this code?

Thank you.

Sub HIDE_ALL()

With ThisWorkbook
.Unprotect password:="1111"

If Worksheets("WB_1").Visible = True Then
Worksheets("WB_1").Visible = False
End If

If Worksheets("WB_2").Visible = True Then
Worksheets("WB_2").Visible = False
End If

If Worksheets("WB_3").Visible = True Then
Worksheets("WB_3").Visible = False
End If

If Worksheets("WB_4").Visible = True Then
Worksheets("WB_4").Visible = False
End If

If Worksheets("WB_5").Visible = True Then
Worksheets("WB_5").Visible = False
End If

If Worksheets("WB_6").Visible = True Then
Worksheets("WB_6").Visible = False
End If

If Worksheets("WB_7").Visible = True Then
Worksheets("WB_7").Visible = False
End If

.protect password:="1111"
End With

End Sub

 

[Joe4]

How many other sheets are there in the workbook?
How are they named?
We can simply tell it to loop through all sheets and hide all the ones meeting certain name criteria.

 

[Fluff]

How about

Sub HIDE_ALL()
   Dim i As Long
   With ThisWorkbook
      .Unprotect Password:="1111"
      For i = 1 To 7
         .Worksheets("WB_" & i).Visible = xlSheetHidden
      Next i
      .Protect Password:="1111"
   End With
End Sub

 

[Martin_H]

The amount of worksheets vary.

There will always be at least 8 worksheets starting from WB_1 up to WB_7 AND WB_0 which should not be hidden at all.

Then, there will be up to 8 other worksheets that should not be hidden.

These worksheets are named this way: today's date | three-letter-symbol

For Example: 13.8.21 | AL1

 

[Martin_H]

How about

Sub HIDE_ALL()
   Dim i As Long
   With ThisWorkbook
      .Unprotect Password:="1111"
      For i = 1 To 7
         .Worksheets("WB_" & i).Visible = xlSheetHidden
      Next i
      .Protect Password:="1111"
   End With
End Sub

Looking good Fluff.

How would it work if instead WB_1 or WB_2 name of sheet there will be some random text?

For Example WB_Machines or WB_Service.

Thank you.

 

[Fluff]

How about

Sub HIDE_ALL()
   Dim Ws As Worksheet
   With ThisWorkbook
      .Unprotect Password:="1111"
      For Each Ws In .Worksheets
         If Ws.Name Like "WB_*" Then Ws.Visible = xlSheetHidden
      Next Ws
      .Protect Password:="1111"
   End With
End Sub

 

[Martin_H]

How about

Sub HIDE_ALL()
   Dim Ws As Worksheet
   With ThisWorkbook
      .Unprotect Password:="1111"
      For Each Ws In .Worksheets
         If Ws.Name Like "WB_*" Then Ws.Visible = xlSheetHidden
      Next Ws
      .Protect Password:="1111"
   End With
End Sub

Awesome.

One small wish.

Would it be possible to add maybe an OR operator because there is one worksheet called like no other "CALC".

 

[hrayani]

If you want you can simply type in the exact sheet names in the VBA code

Sub HIDE_ALL()
    Dim ws As Worksheet
    Set WSArray = Worksheets(Array("WB_1", "WB_2", "WB_3", "WB_4", "WB_5", "WB_6", "WB_7"))
        With ThisWorkbook
        .Unprotect Password:="1111"

    For Each ws In WSArray
    ws.Visible = xlSheetHidden
    Next ws
        .Protect Password:="1111"
End With
End Sub

 

[Fluff]

Would it be possible to add maybe an OR operator

Any other changes?

 

[Martin_H]

If you want you can simply type in the exact sheet names in the VBA code

Sub HIDE_ALL()
    Dim ws As Worksheet
    Set WSArray = Worksheets(Array("WB_1", "WB_2", "WB_3", "WB_4", "WB_5", "WB_6", "WB_7"))
        With ThisWorkbook
        .Unprotect Password:="1111"

    For Each ws In WSArray
    ws.Visible = xlSheetHidden
    Next ws
        .Protect Password:="1111"
End With
End Sub

Looking good. Thank you hrayani.