Helps fix VBA code when inserting an image to another computer without causing the image to be blank

[Excelpromax123]

I used this code to insert employee images into the payroll. On the file I made, it was OK, but when I brought this file to another computer, the image was blank. Please help me, thank you very much

Sub chenhinhanh()
    On Error Resume Next
        Dim ws As Worksheet
        Dim picPath As Variant
        Dim pic As Picture
        Set ws = ThisWorkbook.Sheets("bangluong")
        picPath = Application.GetOpenFilename("Hinh Anh (*.jpg; *.jpeg; *.png), *.jpg; *.jpeg; *.png", , "Chon Hinh Anh")
        If picPath = False Then Exit Sub
        
        Set pic = ws.Pictures.Insert(picPath)

        With pic
            .Left = ws.Range("B2").Left
            .Top = ws.Range("B2").Top
            .Placement = xlMoveAndSize
            .Name = "NhanVien"
        End With
End Sub

 

[DanteAmor]

Try this:

Sub chenhinhanh()
  Dim ws As Worksheet
  Dim picPath As Variant
  Dim pic As Picture
  Dim w As Double, h As Double
 
  Set ws = ThisWorkbook.Sheets("bangluong")
  picPath = Application.GetOpenFilename("Hinh Anh (*.jpg; *.jpeg; *.png), *.jpg; *.jpeg; *.png", , "Chon Hinh Anh")
  If picPath = False Then Exit Sub

  '***Just to get the width and height of the image 

  Set pic = ws.Pictures.Insert(picPath)
  w = pic.Width
  h = pic.Height
  pic.Delete
  
  'If you know or want another width and height in the image you must put it in the variables w and h
  '***
 
  With ws.Shapes.AddPicture(picPath, False, True, ws.Range("B2").Left, ws.Range("B2").Top, w, h)
    .Placement = xlMoveAndSize
    .Name = "NhanVien"
  End With
End Sub