Help with using array formulas with 3 arrays

[Squiggles17]

This is a table that effectively has the same problem as the one I'm experiencing.

[TABLE="width: 500"]
<tbody>[TR]
[TD]100[/TD]
[TD]Blue[/TD]
[TD]1[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B1),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]120[/TD]
[TD]Red[/TD]
[TD]2[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B2),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]10[/TD]
[TD]Green[/TD]
[TD]3[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B3),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]150[/TD]
[TD]Blue[/TD]
[TD]5[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B4),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]110[/TD]
[TD]Green[/TD]
[TD]7[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B5),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]100[/TD]
[TD]Red[/TD]
[TD]11[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B6),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]80[/TD]
[TD]Red[/TD]
[TD]13[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B7),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]50[/TD]
[TD]Green[/TD]
[TD]17[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B8),$C$1:$C$9,1))[/TD]
[/TR]
[TR]
[TD]90[/TD]
[TD]Blue[/TD]
[TD]19[/TD]
[TD]=PRODUCT(IF(AND($A$1:$A$9>=100,$B$1:$B$9=B9),$C$1:$C$9,1))[/TD]
[/TR]
</tbody>[/TABLE]

My intention of the formula in D1 is for it to find the product of all the Values in Column C for which the Corresponding Cell in A is greater than or equal to 100 and the Corresponding cell in B is the same value as B1.

Currently all the values in column D show 1 but I want them to display the following,
D1 5
D2 22
D3 7
D4 5
D5 7
D6 22
D7 22
D8 7
D9 5
Any help on what I'm doing wrong with my formula and how to fix it would be great.
If what I want is not possible in one formula, adding another column would be alright.
Thanks

IMPORTANT: As I am using array formulas, when leaving the cells press CTRL + SHIFT + ENTER to make curly brackets appear around the formula

 

[Weazel]

maybe something like

=PRODUCT(IF($A$1:$A$9>=100,IF($B$1:$B$9=B1,$C$1:$C$9,""))) Control Shift Enter

 

[barry houdini]

You can't use AND here because AND returns a single value, not an array

You can use nested IFs or * to simulate AND, i.e. either

=PRODUCT(IF($A$1:$A$9>=100,IF($B$1:$B$9=B1,$C$1:$C$9,1)))

or

=PRODUCT(IF(($A$1:$A$9>=100)*($B$1:$B$9=B1),$C$1:$C$9,1))

 

[Squiggles17]

Thank you to both of you, and thanks barry for the explanation