Help with outlook

[rcirone]

Does anyone know of a way to add a template of events to an outlook calendar? we are going to track important dates for an email campaign and instead of making them up each time I would looking for a faster way to add them to a calendar as a bulk item of events on specific dates depending on the start date.

 

[Micron]

Not sure what that all means. I have a wb with code that loops over column A to get calendar events titles and col B to get the date/time of the event. The code also sets the recurrence pattern (for me it is yearly). If that seems like what you're asking for I can post it.

 

[rcirone]

Not sure what that all means. I have a wb with code that loops over column A to get calendar events titles and col B to get the date/time of the event. The code also sets the recurrence pattern (for me it is yearly). If that seems like what you're asking for I can post it.

Yes please

 

[Micron]

These events just happen to be recurring birthday reminders. Note: they are Outlook AppointmentItems if that matters.

Sub ImportBirthdaysToCalendar()
    Dim objWorksheet As Excel.Worksheet
    Dim nRow As Integer, nLastRow As Integer
    Dim objOutlookApp As Outlook.Application
    Dim objCalendar As Outlook.Folder
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim objRecurrencePattern As Outlook.RecurrencePattern
 
    'Get the specific sheet
    Set objWorksheet = ThisWorkbook.Sheets(1)
    nLastRow = objWorksheet.Range("A" & objWorksheet.Rows.Count).End(xlUp).Row
 
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objCalendar = objOutlookApp.Session.GetDefaultFolder(olFolderCalendar)
 
    For nRow = 2 To nLastRow
        Set objBirthdayEvent = objCalendar.Items.Add("IPM.Appointment")
 
        'Create birthday events
        With objBirthdayEvent
            .Subject = objWorksheet.Range("A" & nRow) & Chr(39) & "s Birthday"
            .Body = "Born " & Format(Int(objWorksheet.Range("B" & nRow)), "mmmm dd, yyyy")
            .AllDayEvent = False
            .Start = objWorksheet.Range("B" & nRow)
            .BusyStatus = olFree
            .ReminderSet = True
            .ReminderMinutesBeforeStart = 4320
         Set objRecurrencePattern = .GetRecurrencePattern
         With objRecurrencePattern
            .RecurrenceType = olRecursYearly
            .PatternStartDate = objWorksheet.Range("B" & nRow)
            .NoEndDate = True
         End With
            .Save
        End With
    Next
End Sub

I changed the names to make them anonymous. The data is arranged like so (Column C is just a helper column to sort them for me by month/day). The time portion in the date isn't the time they were born, it is the time that Outlook fires the reminder. 4320 is the number of minutes for the reminder, so 3 days.

NAME	BIRTHDAY	sort
DAISY DUCK	1/01/1965 8:00:00 AM​	01.01
DAFFY DUCK	1/14/1978 8:00:00 AM​	01.14
DONALD DUCK	1/23/1969 8:00:00 AM​	01.23