Help with FILTER Formula

[ozzborn]

I cannot use Mini-sheets our IT admin will not allow us to install outside programs.

I am using WIN365 and WIN10.

Here is a snap shot of a range, the red dates are within the 30 day window.

What I am trying to do is isolate the Topics with red dates to one result.

This next picture is my data set and it is a table named data. I have developed 2 formulas to try and isolate just the dates within 30 days. I am trying to combine the formulas into one large formula and I have not been able to do that.

=FILTER(data,(data[Iteration '#1]>=K1)*(data[Iteration '#1]<=K2),"")

The above formula returns just the dates within 30 days from Today() using the Iteration #1 column.

K1 is the Today formula = TODAY()
K2 is K1 plus 30 = K1+30

=FILTER(data,(data[Iteration '#2]>=K1)*(data[Iteration '#2]<=K2),"")

The second above formula does the same with the Iteration #2 column.
What I am trying to do is combine these two formulas into one big formula so it returns the red values to one outcome.
I cannot figure out how to combine the formulas.

One last thing how do I get the 00-Jan-00 to no be returned, and just leave the cell blank.

I am grateful for any help
Ozz

 

[Fluff]

How about

=FILTER(data,((data[Iteration '#1]>=K1)*(data[Iteration '#1]<=K2))+((data[Iteration '#2]>=K1)*(data[Iteration '#2]<=K2)),"")

 

[ozzborn]

That worked.
Here is my current formula;
=FILTER(data,((data[Iteration '#1]>=K1)*(data[Iteration '#1]<=K2))+((data[Iteration '#2]>=K1)*(data[Iteration '#2]<=K2))+((data[Iteration '#3]>=K1)*(data[Iteration '#3]<=K2))+((data[Iteration '#4]>=K1)*(data[Iteration '#4]<=K2))+((data[Iteration '#5 ]>=K1)*(data[Iteration '#5 ]<=K2)),"")

My current range is:

The above formula located in J6 below returns the range below. Works pretty good.
It is also dynamic so I can add to the range and it automatically populates the results.
Any ideas on how I can handle the "00-Jan-00" and have it return blank cells?
I would like the cells to be blank / empty.
I tried conditional formatting on the results and could get nothing to work.
Thank you,
Ozz

 

[Fluff]

One option is to use

=LET(f,FILTER(data,((data[Iteration '#1]>=K1)*(data[Iteration '#1]<=K2))+((data[Iteration '#2]>=K1)*(data[Iteration '#2]<=K2))+((data[Iteration '#3]>=K1)*(data[Iteration '#3]<=K2))+((data[Iteration '#4]>=K1)*(data[Iteration '#4]<=K2))+((data[Iteration '#5 ]>=K1)*(data[Iteration '#5 ]<=K2)),""),if(f=="","",f))

another option is to use a custom cell format.

 

[ozzborn]

Fluff, that worked.
Thank you

P.S. I am curious ,can you give me a hint on the custom cell format?

Again thanks,
Ozz

 

[Fluff]

For the cell format you can use 0;-0;;@

 

[ozzborn]

For the cell format you can use 0;-0;;@

Fluff, thank you.

 

[Fluff]

You're welcome & thanks for the feedback.