Help with CountIfs statement regarding a table

[JenniferMurphy]

I would like to a formula for 3 sums:

1. Votes where Biden has the greater projected vote share
2. Votes where Trump has the greater projected vote share
3. Votes where the percentages are equal.

The table on the right has the correct totals. It shows which cells should go it each category. But I would like an expression that will work for the whole table. The one below is just a few rows.

This gets a zero: =SUMIFS(Table25[Electoral Votes],Table25[Projected Vote Share Biden],F9>G9)

This gets a #VALUE error: =SUMIFS(Table25[Electoral Votes],Table25[[Projected Vote Share Biden]:[Projected Vote Share Trump]],F9>G9)

2024 Presidential Election Polling.xlsx
	C	D	E	F	G	H	I	J	K	L
8	State	Electoral Votes	Current Leader	Projected Vote Share Biden	Projected Vote Share Trump	Electoral Votes Biden	Electoral Votes Trump
9	Alabama	9	Trump	35%	64%	0	9			Sum
10	Alaska	3	Trump	41%	55%	0	3		Biden	89
11	Arizona	11	Toss-up	49%	48%	5.5	5.5		Trump	18
12	Arkansas	6	Trump	35%	64%	0	6		Tie	46
13	California	54	Biden	62%	36%	54	0
14	Colorado	10	Biden	57%	41%	10	0
15	Connecticut	7	Biden	60%	38%	7	0
16	Delaware	3	Biden	62%	36%	3	0
17	Florida	30	Toss-up	49%	49%	15	15
18	Georgia	16	Toss-up	49%	49%	8	8
19	Hawaii	4	Biden	66%	33%	4	0
Sheet2

Cell Formulas
Range	Formula
H9:H19	H9	=IF([@[Current Leader]]="Biden",[@[Electoral Votes]],IF([@[Current Leader]]="Toss-up",[@[Electoral Votes]]/2,0))
I9:I19	I9	=IF([@[Current Leader]]="Trump",[@[Electoral Votes]],IF([@[Current Leader]]="Toss-up",[@[Electoral Votes]]/2,0))
L10	L10	=D11+D13+D14+D15+D16+D19
L11	L11	=D9+D10+D12
L12	L12	=D17+D18

 

[RoryA]

You could use sumproduct:

=SUMPRODUCT(Table25[Electoral Votes],--(Table25[Projected Vote Share Biden]>Table25[Projected Vote Share Trump]))

 

[JenniferMurphy]

You could use sumproduct:

=SUMPRODUCT(Table25[Electoral Votes],--(Table25[Projected Vote Share Biden]>Table25[Projected Vote Share Trump]))

That works, thanks. If there to way to use SumIfs?

 

[RoryA]

Not without helper columns because the criteria you are passing are True/False values, and none of your columns contain True/False.

 

[JenniferMurphy]

Not without helper columns because the criteria you are passing are True/False values, and none of your columns contain True/False.

Got it, thanks.