Help with code

[decadence]

Hi can someone help to turn it into to an array, I have tried to do an array but got nowhere, if not maybe help with tidying it up.
Thanks

    With ActiveSheet.UsedRange
        Set c = .Find("Ref-Designator", LookIn:=xlValues)
    ActiveSheet.Range(c.Address).EntireColumn.Cut Destination:=Range("AA:AA")
        Set c = .Find("X Offset", LookIn:=xlValues)
    Application.ScreenUpdating = False
    ActiveSheet.Range(c.Address).EntireColumn.Cut Destination:=Range("AB:AB")
        Set c = .Find("Y Offset", LookIn:=xlValues)
    Application.ScreenUpdating = False
    ActiveSheet.Range(c.Address).EntireColumn.Cut Destination:=Range("AC:AC")
        Set c = .Find("Angle", LookIn:=xlValues)
    Application.ScreenUpdating = False
    ActiveSheet.Range(c.Address).EntireColumn.Cut Destination:=Range("AD:AD")
    End With

 

[JackDanIce]

One suggestion, try replacing all of your code with:

Dim x       As Long
    Dim var     As Variant
    Dim temp    As Variant
    Dim rng     As Range
    
    With ActiveSheet
        
        For Each var In Array("Ref-Designator|AA1", "X Offset|AB1", "Y Offset|AC1", "Angle|AD1")
            On Error Resume Next
                Set rng = .Cells.find(what:=Split(var, "|")(0), LookIn:=xlValues)
                If Not rng Is Nothing Then
                    x = .Cells(.Rows.Count, rng.Column).End(xlUp).row
                    .Cells(1, rng.Column).Resize(x).Cut .Cells(1, Split(var, "|")(1)).Resize(x).Paste
                    Application.CutCopyMode = False
                    Set rng = Nothing
                End If
            On Error GoTo 0
        Next var
    End With

 

[decadence]

Hi Jack, your code doesn't do anything, All I want to do is find the headers and move the entire column.

 

[JackDanIce]

This works for me:

Sub Macro1()

    Dim x       As Long
    Dim var     As Variant
    Dim temp    As Variant
    Dim rng     As Range
    Dim arr()   As Variant
    
    With ActiveSheet
        
        For Each var In Array("Ref-Designator|AA", "X Offset|AB", "Y Offset|AC", "Angle|AD")
            On Error Resume Next
                Set rng = .Cells.find(what:=Split(var, "|")(0), LookIn:=xlValues)
                If Not rng Is Nothing Then
                    x = .Cells(.Rows.Count, rng.Column).End(xlUp).row
                    With .Cells(1, rng.Column).Resize(x)
                        arr = .Value
                        .ClearContents
                    End With
                    .Cells(1, Split(var, "|")(1)).Resize(UBound(arr, 1), UBound(arr, 2)).Value = arr
                    Erase arr
                    Set rng = Nothing
                End If
            On Error GoTo 0
        Next var
    End With
        
End Sub

 

[decadence]

This works perfectly, Thank you it's much appreciated

 

[JackDanIce]

You're welcome