Help required: Floating button to do a google search

[Steven0605]

Hi all,

I have a rather large spreadsheet (circa 100k lines) and each line has a different item on it. I need to review each item and make a decision about the department each item would fall into. The problem is that for about 75% of the items I need to do a google search to determine what the item is in the first place.

I guess my question is: Does anyone have any code that would insert a floating button into the spreadsheet, so that when it is clicked it will use the currently selected cells contents and open chrome/IE (or use an already open instance of chrome/IE) and do a google search using the contents of the cell?

My current method is: Select cell, CTRL-C, AltTab to Chrome, CTRL-V in chrome, then review search results. I need to do these reviews a few times a year so I'm hoping to combine the first 4 steps (those in bold) into one quick button click in excel if possible.

Any help is appreciated.

Thanks in advance.

 

[MrKowz]

Welcome to the forums!

Here's how I would handle this. Resize your row 1 and insert a button there, label it whatever you want. Freeze row 1, so as you scroll down, the button (and headers) stay visible.

Next, copy the following code into a new module and assign the "GoogleSearch" macro to the button.

Hope this helps!

Public Sub BrowserPicker(browser As String, URL As String)

Dim iePath  As String, _
    chPath  As String, _
    bPath   As String
    
iePath = Environ$("ProgramW6432") & "\Internet Explorer\iexplore.exe"
chPath = Environ$("ProgramFiles") & "\Google\Chrome\Application\chrome.exe"

Select Case UCase(browser)
    Case "IE"
        bPath = iePath
    Case "CHROME"
        bPath = chPath
    Case Else
        bPath = iePath
End Select

Call Shell(bPath & " " & URL, vbNormalFocus)

End Sub

Public Sub GoogleSearch()
Dim tmpURL      As String, _
    tmpSearch   As String
    
tmpURL = "https://www.google.com/search?q="
tmpSearch = Replace(Selection.Value, " ", "+")

tmpURL = tmpURL & tmpSearch

BrowserPicker "CHROME", tmpURL
End Sub

 

[Steven0605]

Thank you, that did exactly what I needed.