Help Combining 2 VBA Change codes

[tylerstoehr]

Hello,

I am trying to combine a couple of simple VBA Change codes but am unable to get both working at the same time. The one coded first works, the second doesn't.

Private Sub Worksheet_Change(ByVal Target As Range)


    With Target
        If Intersect(Target, Range("A:A,F:F")) Is Nothing Or Target.Cells.Count > 1 Then Exit Sub
            Application.EnableEvents = False
            Target.Value = UCase(Target.Value) 'Sets range values to uppercase
            Application.EnableEvents = True
    End With
    
    With Target
        If Intersect(Target, Range("C:C")) Is Nothing Or Target.Cells.Count > 1 Then Exit Sub
            Application.EnableEvents = False
            Target.Value = StrConv(Target.Value, vbProperCase) 'Sets range to proper case
            Application.EnableEvents = True
    End With
    






End Sub

Very simple, I am very new to this all help is greatly appreciated.

Thank you in advance!

 

[Joe4]

That's because you are telling it to Exit the Sub if the first condition is not met.
Try:

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Cells.Count > 1 Then Exit Sub

    If Not Intersect(Target, Range("A:A,F:F")) Is Nothing Then
        Application.EnableEvents = False
        Target.Value = UCase(Target.Value) 'Sets range values to uppercase
        Application.EnableEvents = True
    End If
    
    If Not Intersect(Target, Range("C:C")) Is Nothing Then
        Application.EnableEvents = False
        Target.Value = StrConv(Target.Value, vbProperCase) 'Sets range to proper case
        Application.EnableEvents = True
    End If

End Sub

 

[tylerstoehr]

Ahhhhhh!

The old reverse of logic to allow passthrough. Thank you!

I was expecting a solution that used If ... Then goto X, but this solution is much more elegant!

THank you so much!

 

[Joe4]

You are welcome!